[精英VBA专题]字符串用法大全(整理中,请参与进来)

chenhuafu

感谢chenhuafu兄开了一个不错的专题,并为我们开了一个好头. GO ON.分享你知道的字符串的技巧给大家,让我们尽力揽尽字符串... 本贴初步决定置顶一个月,然后链至指引贴.为了日后看贴方面,置顶期间,谢绝灌水哦. -------------------------------------------------------------------------------------------------- 查找特定字符串的代码 这是我在QQ群（蓝色幻想读者群）里面回复—— 小桥.流水(290931055) 的求助： Sub rrr() Dim pos%, w$ w = "BSQ1-3-(5，6)" pos = Application.WorksheetFunction.Find("SQ", w) MsgBox pos End Sub 还可以 Sub rrr() Dim pos%, w$ w = Sheet1.Cells(1, 1).Value 'A1的内容为：BSQ1-3-(5，6)" pos = Application.WorksheetFunction.Find("SQ", w) MsgBox pos End Sub *************************补充一下*************************************************************** instr函数：指定一字符串在另一字符串中最先出现的位置 InStr（开始位置，查找的字符串, 搜索的子字符串) 例：InStr(１， w，"SQ")

chenhuafu

某个字符的出现次数 统计一个字符串中的某个字符的出现次数,比如"asdsd" s出现两次,应该用哪个函数? Sub ttt() Dim Q$, I%, J%, W% Q = "asdsd" I = Len(Q) For J = 1 To I If Mid(Q, J, 1) = "s" Then W = W + 1 Next MsgBox W End Sub *************************补充一下*************************************************************** 以上循环也可以用以下语句实现: Sub ttt() Msgbox Len("dSdSd") - Len(Replace("dSdSd", "S", "")) End Sub 注: Replace是在一个字符串中,对指定的字符串进行替换为其他指定的字符串.本例中在字符串"dSdSd"中,用""替换"S",然后用原来的总长度(LEN函数求得)减去替换后的总长度,即为S的个数.

chenhuafu

某个字符的出现次数（自定义函数法） Function test(X, S As String) As Integer Dim I%, J% I = Len(X) For J = 1 To I If Mid(X, J, 1) = "s" Then test = test + 1 Next End Function 用这个自定义函数也可以 比如A1的内容是：asdsd 你在a2输入： =test(a1,"s") 或者想计算 d 有几个 =test(a1,"d") 自定义函数比宏（过程sub ***() …… end sub）灵活一点 ***************************************************************** 根据蓝色幻想版主的提示，还可以自定义函数改修为： Function test(X, S As String) As Integer test = Len(X)-len(replace(x,s,"")) End Function

chenhuafu

又要问一个了:取一个字符串中某个位置的定长字符串,有那个函数么?比如:"asdfg",从第3个字符开始取长度为2的字符串.

回复：

工作表函数 =mid("asdfg",3,2)

VBA中也有这个函数，l例如：

Sub t()
    Dim D$
    D = Mid("asdfg", 3, 2)
    MsgBox D
End Sub

[此贴子已经被兰色幻想于2007-2-13 20:49:02编辑过]

chenhuafu

"34"转化为34,有转化函数么? 回复： *1 就可以了 还有多种方法： *1 /1 +0 -0 --"34" 等等都可以 还可以采用复制->选择性粘贴等等 *************************补充一下*************************************************************** 在VBA中转化数值的函数有以下几个: CDbl Double 负数从 -1.79769313486231E308 至 -4.94065645841247E-324；正数从 4.94065645841247E-324 至 1.79769313486232E308。 CDec Decimal 零变比数值，即无小数位数值，为 +/-79,228,162,514,264,337,593,543,950,335。对于 28 位小数的数值，范围则为 +/-7.9228162514264337593543950335；最小的可能非零值是 0.0000000000000000000000000001。 CInt Integer -32,768 至 32,767，小数部分四舍五入。 CLng Long -2,147,483,648 至 2,147,483,647，小数部分四舍五入

chenhuafu

字符串的反向查找函数有么? "dSdSd",反向查找第一个S,返回:4. 回复： Sub TTT() Dim T$, I%, J%, K% T = "dSdSd" I = Len(T) For J = 1 To I If Right(T, 1) = "S" Then K = I - J + 1 Exit For Else T = Left(T, I- J) End If Next MsgBox K End Sub *************************补充一下*************************************************************** 在VBA中InStrRev是执行反向查找的函数. 用法为:InStrRev(搜索的字符串, 查找的字符或字符串,开始查找的位置(倒数的位置)) 本例可简化为: InStrRev("dSdSd", "S")

qee用

Like运算符是字符串比较时经常使用的运算符，也是VBA较难掌握的运算符。 语法： 结果 = 字符串 Like 模式 如果字符串与模式匹配，结果为True，否则为False。但是如果Like两端的字符串和模式有一个为Null，则结果为Null。 VBA内建的模式匹配功能提供了丰富的字符串比较方式，在模式表达式中可以使用通配符、字符列表（或字符区间）的任何组合来匹配字符串。 模式中的字符 与模式匹配的字符串中的字符 ? 任何单一字符 * 零个或多个字符 # 任何一个数字（0-9） [字符列表] 字符列表中的任何一个字符 [!字符列表] 不在字符列表中的任何一个字符 其它字符(串) 与自身匹配 1.Like在字符串比较时受Option Compare语句的影响，在默认情况下（Option Compare Binary），字符比较根据内部二进制表示法（ASCII码）进行，是区分大小写的，此时 "A" Like "a" 的结果为False。如果声明了Option Compare Text，则不区分大小写比较，"A" Like "a" 的结果为True。 后面的讨论假设默认情况下。 2.如果模式中没有使用通配符（?、*、#）和字符列表，此时Like运算符等价于=（等号）运算符。下面表达式的结果相同。 s Like "AB" s = "AB" 3.字符列表 理解字符列表的用法是学会Like的难点，所以，下面我会多花些笔墨帮你理解它。 (1)一个字符列表匹配的是字符串中的一个字符，不管字符列表中实际有多少个字符。 "A" Like [ABCDEGHIJ2345] 结果为True "AB" Like [ABCDEGHIJ2345] 结果为False 唯一的例外是[]被看作长度为零的字符串。 (2)字符列表中的单个字符，没有顺序要求，上面[ABCDEGHIJ2345]和[ACDEGHIJ2345B]、[3ABCDEGHIJ245]...等等是一样的表达。 (3)字符列表中一段连续的字符（称为区间，一个字符列表可以有多个区间，广义上，单个字符也可被看作一个区间），可以使用连字符（-，减号）简化表达式，如上面的表达式[ABCDEGHIJ2345]可以简化为[A-EG-J2-5]，连字符要遵循从小到大的顺序（升序），即连字符(-)右端的字符应大于左端的字符，如其中的A-E不能写成E-A，后者系统会报错。但多个区间之间没有顺序要求，这意味着[G-J2-5A-E]、[2-5G-JA-E]...等是同一表达。但下面的表达是错误的，同时也是常见的： [A-E G-J 2-5]、[A-E,G-J,2-5]、[A-E;G-J;2-5] 也许只是一种习惯或想当然，第一个除了要求表达的ABCDEGHIJ2345外，还多加了一个空格；后面两个分别多了逗号(,)和分号(;)。 "," Like [A-EG-J2-5] 结果为False "," Like [A-E,G-J,2-5] 结果为True (4)被中括号（[]）括起的字符列表中的字符，?、*、#不被理解为通配符，而是表示符号自身。如果要表示-（减号，连字符），可以放在列表的开头或结尾。如[ABC-]、[-ABC]。 "3" Like "?" 结果为True "3" Like "[?]" 结果为False "?" Like "[?]" 结果为True 这一特性通常被用作特殊字符的表示，例如，除了通配符外， 左括号 ([)等特殊字符都可以将它们用方括号括起来。要注意的是，也不能在一个组内使用右括号 (]) 与自身匹配，但在组外可以作为个别字符使用。 (5)在字符列表加上!(感叹号）开头，表示要匹配的是不在字符列表中的任一字符（不包括开头的!自身）。[!!]表示除了感叹号之外的任一字符。 5.例子 下面是EXCEL/VBA帮助中举的几个Like运算符的例子，对照结果看看，如果和你想的结果都一样，说明你已经基本掌握了Like用法。 Dim MyCheck MyCheck = "aBBBa" Like "a*a" ' 返回 True。 MyCheck = "F" Like "[A-Z]" ' 返回 True。 MyCheck = "F" Like "[!A-Z]" ' 返回 False。 MyCheck = "a2a" Like "a#a" ' 返回 True。 MyCheck = "aM5b" Like "a[L-P]#[!c-e]" ' 返回 True。 MyCheck = "BAT123khg" Like "B?T*" ' 返回 True。 MyCheck = "CAT123khg" Like "B?T*" ' 返回 False。 6.思考题 假设有一字符串s，写出表达式，判断s是否是仅由字母组成并且以字母e（E）结尾的字符串。 答案在本专题后公布

qee用

是的，你没有看错，我是说Mid语句，而不是Mid函数。 让我们看一个例子。 已知：字符串s="12345"，整数i=2 要求:将s的第i个字符替换为"d" 通常的方法(Mid函数)： s=left(s,i-1) & "d" & mid(s,i+1) Mid语句的方法： Mid(s, i, 1) = "d" 下面我们来看看帮助中介绍的的Mid语句 Mid 语句 在一 Variant (String) 变量中以另一个字符串中的字符替换其中指定数量的字符。 语法 Mid(stringvar, start[, length]) = string stringvar 必要参数。被更改的字符串变量名。 start 必要参数；Variant (Long)。stringvar 中被替换的字符开头位置。 length 可选参数；Variant (Long)。被替换的字符数。如果省略，string将全部用上。 string 必要参数。字符串表达式，替换部分 stringvar 的址??? 说明 被替换的字符数量总是小于或等于 stringvar 的字符数。 示例 Sub UseMid() Dim s$ s = "12345" Mid(s, 2, 1) = "d" Debug.Print s '1d345 --替换1个字符,第2个字符被替换为d s = "12345" Mid(s, 2, 1) = "df" Debug.Print s '1d345 --只替换1个字符,第2个字符被忽略 s = "12345" Mid(s, 2, 2) = "df" Debug.Print s '1df45 --替换2个字符 s = "12345" Mid(s, 5, 1) = "df" Debug.Print s '1234d --只替换1个字符,第2个字符被忽略 s = "12345" Mid(s, 5, 2) = "df" Debug.Print s '1234d --只替换1个字符,第2个字符超出s长度,被忽略 s = "12345" Mid(s, 6, 1) = "d" '出错 --6超出s长度 Debug.Print s End Sub 相关 简单的介绍一下相关的三个函数，也许你已经对它们很熟悉了，我写在这儿的目的只是让这段文字看起来更完整。关于它们的具体细节，请参考帮助文档。 1.Mid函数 语法：Mid(string, start[, length]) 返回从字符串string的start位置取出的指定长度length的字符，如省略length或length 超过文本的字符数（包括 start 处的字符），将返回字符串中从 start 到尾端的所有字符。 2.Right函数 语法:Right(string, length) 3.Left函数 语法:Left(string, length) 后面两个函数分别返回字符串string右（左）边取出的指定数量length的字符。

chenhuafu

做qee用7楼的作业：

Sub T()
    Dim R$, W$, I%, J%, K%
    R = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    W = UCase(InputBox("请输入字符"))
    I = Len(W)
    For J = 1 To I
        K = InStr(1, R, Mid(W, J, 1))
      '  MsgBox K
        If K < 1 Then
            MsgBox "你输入的字符含有非字母"
            Exit Sub
        End If
    Next
    If Right(W, 1) = "E" Then
    MsgBox "你输入的字符都是字母并且最后一个字符是“e”或者“E”"
    Else
    MsgBox "你输入的字符都是字母但最后一个字符不是“e”或者“E”"
    End If
End Sub

 

--------------
chen兄结果正确.要用Like运算符来写的话,怎么写呢?  qee用

[此贴子已经被admin于2007-2-13 20:51:14编辑过]

chenhuafu

Sub T()
    Dim R$, W$, I%, J%, TTT
    W = UCase(InputBox("请输入字符"))
    I = Len(W)
    For J = 1 To I
        R = Mid(W, J, 1)
       ' MsgBox R
      TTT = R Like "[!A-Z]"
     ' MsgBox TTT
        If TTT Then
            MsgBox "你输入的字符含有非字母"
            Exit Sub
        End If
    Next
    If Right(W, 1) = "E" Then
    MsgBox "你输入的字符都是字母并且最后一个字符是“e”或者“E”"
    Else
    MsgBox "你输入的字符都是字母但最后一个字符不是“e”或者“E”"
    End If
End Sub

[此贴子已经被admin于2007-2-13 20:51:32编辑过]