[已解决]新人求助：对象变量或with块变量未设置

442039099

'在黄色区域中查找值为2的单元格，并将这些单元格值变为5
Sub chaozhao3()
    Dim rg As Range
    Dim myaddress As String
    Set rg = Range("a14:f24").Find(2)
    If rg Is Nothing Then
        Debug.Print "not 2"
    Else
        myaddress = rg.address
        Do
            rg.value = 5
            Set rg = Range("a14:f24").FindNext(rg)
        Loop While Not rg Is Nothing And rg.address <> myaddress          每次运行到这句代码就会报错：对象变量未设置
    End If
End Sub

最佳答案

月排行榜 / 总排行榜

SlimEvans

2022-7-27 10:15

你的代码因为前边数字为2的单元格已经改成5了，所以后边查找不存在循环查找，就用不到address
改了一下你的代码
Sub chaozhao3()
    Dim rg As range
    Set rg = range("a14:f24").Find(2)
    If rg Is Nothing Then
        Debug.Print "not 2"
    Else
        Do
            rg.Value = 5
            Set rg = range("a14:f24").FindNext(rg)
        Loop While Not rg Is Nothing
    End If
End Sub
   

跳转到最佳答案楼层

SlimEvans

你的代码因为前边数字为2的单元格已经改成5了，所以后边查找不存在循环查找，就用不到address
改了一下你的代码
Sub chaozhao3()
    Dim rg As range
    Set rg = range("a14:f24").Find(2)
    If rg Is Nothing Then
        Debug.Print "not 2"
    Else
        Do
            rg.Value = 5
            Set rg = range("a14:f24").FindNext(rg)
        Loop While Not rg Is Nothing
    End If
End Sub
   

442039099

有大神路过吗？

我行我速2008

Sub chaozhao3()
    Dim rg As Range
    for each rg in Range("a14:f24")
        if rg .value = 2 then rg.value =5
    next rg
End Sub

442039099

我行我速2008 发表于 2022-7-27 11:16
Sub chaozhao3()
    Dim rg As Range
    for each rg in Range("a14:f24")

大神，没有用find函数啊，用find函数来完成需求

SlimEvans

Sub findnum1()
    Dim r As range, s As String
    Set r = Cells.Find(2, lookat:=xlWhole, searchorder:=xlRows)
    If Not r Is Nothing Then
        Do While Not r Is Nothing
            r.Value = 5
            Set r = Cells.Find(2, after:=r)
        Loop
    Else
        MsgBox "未找到数字2"
    End If
End Sub

442039099

SlimEvans 发表于 2022-7-27 14:44
你的代码因为前边数字为2的单元格已经改成5了，所以后边查找不存在循环查找，就用不到address
改了一下你 ...

大神，我按照你的意思删除掉这句And rg.address <> myaddress，程序能正常运行了，也不报错了。却有个疑问，下面这句代码，不是先判断rg存在，然后才判断address么？
如果rg不存在，就不向后判断了？

Loop While Not rg Is Nothing And rg.address <> myaddress

SlimEvans

442039099 发表于 2022-7-27 15:01
大神，我按照你的意思删除掉这句And rg.address  myaddress，程序能正常运行了，也不报错了。却有个疑问 ...

当所有rg单元格的值改为5后，最后执行Loop While Not rg Is Nothing And rg.address <> myaddress的时候，rg不存在，rg.address就会发生错误，一个不存在的东西怎么会有地址的属性？？？