[已解决]求助：VB词典中，为什么不能用copy？

Sunshain

Sub TET()
Dim arr, k, t, x
arr = Range("a1:b4")
Set d = CreateObject("scripting.dictionary")
For x = 1 To UBound(arr)
d(arr(x, 1)) = Cells(x, 2)
Next x
t = d.keys
k = d.items
k(3).Copy Range("D6")
End Sub

表格就一个4行2列的数据，我看别人的字典代码里直接copy没问题，我这个倒数第二句怎么copy一直提示要求对象，求助大神。

最佳答案

月排行榜 / 总排行榜

大灰狼1976

2022-8-2 22:17

字典里面是单元格对象就能copy了。
Set d(arr(x, 1)) = Cells(x, 2)

跳转到最佳答案楼层

Sunshain

我直接用 Range("D6") = k(3)都能返还值

我行我速2008

K是数组，数组没有copy的方法

Sunshain

我行我速2008 发表于 2022-7-17 13:27
K是数组，数组没有copy的方法

Sub text5()
    Dim arr, rngHead As Range, rngTotal As Range, d As Object, _
    k, t, r&, i&, lr&, lc%, sh As Worksheet

    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    arr = Range("a1").CurrentRegion
    lr = UBound(arr)
    lc = UBound(arr, 2)

    Set rngHead = Rows(1)
    Set rngTotal = Rows(lr)
    Set d = CreateObject("scripting.dictionary")

    For i = 2 To lr
        If Not d.Exists(arr(i, 1)) Then
            Set d(arr(i, 1)) = Cells(i, 1).Resize(, lc)
        Else
            Set d(arr(i, 1)) = Union(d(arr(i, 1)), Cells(i, 1).Resize(, lc))
        End If
    Next

    k = d.Keys
    t = d.Items

    With Sheets
        For i = 0 To d.Count - 1
            With .Add(after:=.Item(.Count))
                .Name = k(i)
                rngHead.Copy .[a1]
                .Cells(1, 1).Resize(, lc).Columns.AutoFit
                t(i).Copy .[a2]
            End With
        Next
    End With
    Sheets(1).Activate
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    End Sub
我试了人家写的这个，蓝色部分用copy，我去运行它能正常运行。

我行我速2008

Sunshain 发表于 2022-7-17 13:57
Sub text5()
    Dim arr, rngHead As Range, rngTotal As Range, d As Object, _
    k, t, r&, i&,  ...

这里的t(i)是工作表吧？没看到具体的表格只能这样猜了。

大灰狼1976

字典里面是单元格对象就能copy了。
Set d(arr(x, 1)) = Cells(x, 2)

我行我速2008

大灰狼1976 发表于 2022-8-2 22:17
字典里面是单元格对象就能copy了。
Set d(arr(x, 1)) = Cells(x, 2)

学习了，版主亲自出马啊！！

Sunshain

大灰狼1976 发表于 2022-8-2 22:17
字典里面是单元格对象就能copy了。
Set d(arr(x, 1)) = Cells(x, 2)

谢谢

大灰狼1976

Sunshain 发表于 2022-8-16 10:30
谢谢

能不能copy单元格和是不是字典没有关系，在这里可以把字典看作一个容器，它里面装了什么才是关键，你把它换成数组或者集合也一样。