求代码，通过判断连续单元格的和的区间，填充数据

estherluo198

比如基础数据这个工作表，A列是箱号，1号箱到N号箱排序，B列是这个箱子对应的货物金额，每个箱子的金额必须小于50，      号码池这个工作表有一组数据，需要通过判断B列的金额，来从号码池依次取号码填充到C列
      规则是：先判断B2+B3的值，如果不超过50，那么继续往下加一个单元格，判断B2+B3+B4的值，
                  如果还不超过50，那么继续往下加，判断B2+B3+B4+B5的值，依次循环
      假设B2+B3+B4+B5大于50了，那么B2+B3+B4成为一组数据，在对应的C2,C3,C4都填充从号码池取回的第一组号码，也就是号码池A2的值
   C2=A2 ,  C3=A2, C4=A2

接着进入下一个循环，因为B2+B3+B4已经成为一组数据了，那么开始判断B5+B6的值，如果不超过50，则判断B5+B6+B7的值
如果B5+B6+B7大于50， 那么B5+B6 成为第二组数据，C5,C6都填充号码池的第二组数据，C5=A3,C6=A3

依次循环

求助大神指教VBA 代码  谢谢

爱疯

Sub test()
    Dim A, B, i, j, k, s, r
    A = Sheets(1).Range("a1").CurrentRegion
    B = Sheets(2).Range("a1").CurrentRegion
    r = 1

    For i = 2 To UBound(A)
        For j = i To UBound(A)
            s = s + A(j, 2)
            If s > 50 Then Exit For
        Next j
        r = r + 1
        For k = i To j - 1
            A(k, 3) = B(r, 1)
        Next k
        s = 0: i = j - 1
    Next i

    Sheets(1).[a1].Resize(UBound(A), UBound(A, 2)) = A
End Sub


举例2.rar (11.39 KB, 下载次数: 1)

2020-3-26 16:42 上传

点击文件名下载附件

estherluo198

简直太感谢了  ，激动 感谢 再激动~~~
如果我要加多一个判断条件呢？
比如先判断箱号， 先把箱号是1的数据筛选出来，做以上循环，  再做箱号2的数据的循环  这个公式又怎么填呢

爱疯

举例3.rar (13.71 KB, 下载次数: 4)

2020-3-27 10:05 上传

点击文件名下载附件
结果是这样吗？






Dim A, B, Num

'入口
Sub test()
    Dim i, x
    Sheets(1).Select
    Range("a1").CurrentRegion.Sort key1:=[a1], order1:=xlAscending, Header:=xlYes
    A = Range("a1").CurrentRegion
    B = Sheets(2).Range("a1").CurrentRegion
    Num = 1
    x = 2
    For i = 3 To UBound(A)
        If A(i - 1, 1) <> A(i, 1) Then Call test2(x, i - 1): x = i
    Next i
    Call test2(x, i - 1)
    Sheets(1).[a1].Resize(UBound(A), UBound(A, 2)) = A
End Sub

'同一箱号(开始, 结束)
Sub test2(x, y)
    Dim i, j, k, s
    For i = x To y
        For j = i To y
            s = s + A(j, 2)
            If s > 50 Then Exit For
        Next j
        Num = Num + 1
        For k = i To j - 1
            A(k, 3) = B(Num, 1)
        Next k
        s = 0: i = j - 1
    Next i
End Sub

爱疯

B列数据怎么产生的？

estherluo198

B列数据属于基础输入  是录入的   ，  太牛了  谢谢你哦

estherluo198

请问这个是啥意思？  s = 0: i = j - 1   出现在代码最后

爱疯

estherluo198 发表于 2020-3-27 13:27
请问这个是啥意思？  s = 0: i = j - 1   出现在代码最后

当记录了一批小于50的记录之后，计数清零，循环的位置 i  = j - 1

estherluo198

了解  谢谢啦