如何用公式找到倒20名学生：学校、姓名、成绩

18997334625

如何用公式从学生成绩登记表中快速显示成绩倒20名学生信息：“学校名称"   " 学生姓名"    " 成绩 "。恳请那位高手给我个公式，谢谢！

INaga2018

没人做我来做吧，按顺序：
AJ3=SMALL($B$2:$S$44,ROW(A1))，下拉

AH3=INDEX($A$1:$S$1,,SMALL(IF($B$2:$S$44=$AJ3,COLUMN($B$1:$S$1)),COUNTIF($AJ$3:AJ3,AJ3)))，数组三键，下拉

AI3=CONCAT(IF(($B$1:$S$1=$AH3)*($B$2:$S$44=$AJ3),$A$2:$R$44,""))，数组三键，下拉

没有concat（）函数的话：
AI3=OFFSET($B$2,MATCH($AJ3,OFFSET($B$2,,MATCH($AH3,$B$1:$S$1,)-1,43),)-1,MATCH($AH3,$B$1:$S$1,)-2)

学生倒数二十名
名次	学校	学生姓名	成绩
第一名	阳 坡	芦桂钰	48
第二名	西 村	石雯静	48.75
第三名	徐家寨	袁世忠	48.75
第四名	大 源	李民辉	49
第五名	西 村	赵宏龙	49
第六名	大 源	马玉霞	50.75
第七名	大 源	窦增炫	54.75
第八名	阳 坡	毛生瑶	55
第九名	阳 坡	郑延洪	55.25
第十名	青石坡	李强	55.25
第十一名	青石坡	薄进鑫	56.5
第十二名	青石坡	马孜强	57
第十三名	阳 坡	李广萍	57.25
第十四名	陈家滩	朱胜超	58
第十五名	甘河沿	李永军	59.5
第十六名	阳 坡	李增琪	60.5
第十七名	甘河沿	刘金花	61
第十八名	大 源	曹理祥	61.5
第十九名	甘河沿	张庭玉	62.25
第二十名	大 源	康诗晗	62.5

心正意诚身修

=SMALL(IFERROR((IF($B$2:$S$44="",999,$B$2:$S$44)+ROW($B$2:$S$44)%%+COLUMN($B$2:$S$44)%%%),999),ROW(A1))    成绩公式.先算成绩.再算学校.再得到姓名.
=INDEX($B$1:$S$1,MAX(IF(AJ3=IFERROR((IF($B$2:$S$44="",999,$B$2:$S$44)+ROW($B$2:$S$44)%%+COLUMN($B$2:$S$44)%%%),999),COLUMN($B$1:$S$1)))-1) 学校.
=OFFSET($A$1,MAX(IF(AJ3=IFERROR((IF($B$2:$S$44="",999,$B$2:$S$44)+ROW($B$2:$S$44)%%+COLUMN($B$2:$S$44)%%%),999),ROW($A$1:$R$43))),MATCH(AH3,$C$1:$S$1,))
姓名公式.因为你有相同的成绩.不能单纯的用分数来判断 .又是多行多列的.处理 起来.相对要复杂一些.

心正意诚身修

INaga2018 发表于 2020-1-14 15:26
没人做我来做吧，按顺序：
AJ3=SMALL($B$2:$S$44,ROW(A1))，下拉

优秀   666
对于重复值.我弄复杂了.不过有的人可能没用到2016及以上版 本.没有CONCAT这个函数

INaga2018

心正意诚身修 发表于 2020-1-14 15:56
优秀   666
对于重复值.我弄复杂了.不过有的人可能没用到2016及以上版 本.没有CONCAT这个函数

版主见笑了，没有新函数水了一个offset+match组合

cutecpu

INaga2018 发表于 2020-1-14 15:26
没人做我来做吧，按顺序：
AJ3=SMALL($B$2:$S$44,ROW(A1))，下拉

讚讚讚{:9_305:}
可能要注意一下，同學校裡同分的情況喔：


祝順心，南無阿彌陀佛！

18997334625

谢谢  心正意诚身修  的鼎力帮助，我的问题解决了，十分感谢！

心正意诚身修

cutecpu 发表于 2020-1-14 18:50
讚讚讚
可能要注意一下，同學校裡同分的情況喔：

嗯嗯 .实际情况是没有这个的.我也考虑了这个问题.

心正意诚身修

INaga2018 发表于 2020-1-14 16:39
版主见笑了，没有新函数水了一个offset+match组合

没见笑哈..公式很优秀 .哈哈.
可惜不是我所在的版 块.给不了你分.

cutecpu

心正意诚身修 发表于 2020-1-15 12:23
没见笑哈..公式很优秀 .哈哈.
可惜不是我所在的版 块.给不了你分.

我來給{:9_303:}