[已解决]使用甚么公式可以得到频率最高年龄往下排？

wooikeat9128

答案结果在C1:C6

求老师帮忙

最佳答案

月排行榜 / 总排行榜

二呗

2017-7-7 12:31

=INDEX(A:A,29-RIGHT(LARGE(IF(FREQUENCY(A$2:A$28,A$2:A$28)>1,FREQUENCY(A$2:A$28,A$2:A$28)/1%+29-ROW($2:$28)),ROW()),2))

跳转到最佳答案楼层

砂海

这样是容易理解一些的,结果 与你略不同 , 同样次数 , 按年龄大的优先了
       ...
辅助列 B2    =IF(COUNTIF(A$1:A2,A2)=1,COUNTIF(A:A,A2)*1000+A2,0)
辅助列 是 第一次 出现的年龄 的计数*1000 + 年龄 , 重复出现的就当做0
   

C1    =MOD(LARGE(B:B,ROW(A1)),1000)
取 (b列第 n 大的值 ) 除以1000 的余数

wooikeat9128

先谢谢老师您，小弟试一试

几米

砂海 发表于 2017-7-7 09:05
这样是容易理解一些的,结果 与你略不同 , 同样次数 , 按年龄大的优先了
       ...
辅助列 B2    =IF(COU ...

辅助列的算法+Mod脱壳的方法很是精妙，学习了，谢啦。

如果不添加辅助列的话，可以这样。
C1==IF(ROW()<=SUM(1/COUNTIF($A$2:$A$28,$A$2:$A$28)),MOD(LARGE(IF(FREQUENCY($A$2:$A$28,$A$2:$A$28)<>0,FREQUENCY($A$2:$A$28,$A$2:$A$28)*1000+($A$2:$A$28),""),ROW(A1)),1000),"")

按Ctrl+Shift+Enter后往下拉。

二呗

=INDEX(A:A,29-RIGHT(LARGE(IF(FREQUENCY(A$2:A$28,A$2:A$28)>1,FREQUENCY(A$2:A$28,A$2:A$28)/1%+29-ROW($2:$28)),ROW()),2))

wooikeat9128

各位老师太厉害了，感谢各位老师们

niko88819

楼主请试一试吧
B2  下拉
{=MODE(IF((A$2:A$50<>"")*(COUNTIF(B$1:B1,A$2:A$50)=0),A$2:A$50),0,0)}

wooikeat9128

谢谢您，老师您真牛