[已解决]【闯关题】 不进位的加法计算 （公式字数在 41 字以内）

丢丢表格

原来值	加 1 后的结果	公式
12345	23456	？？		A 列 是15 位内的自然数 没有负值
100001	211112			每位值加1 ，但不进位。
9999	0			B 列是 A 列 加1 后的 结果
50931	61042
44559900	55660011			要求
939048900	40159011			在 C 列 写公式 达到 B 列的效果
256642391	367753402			字数在 41 字以内。
0	1
9	0
8989089	9090190

  
   解题的简要说明 请看 20楼

最佳答案

月排行榜 / 总排行榜

baksy

2015-7-2 06:06

=SUBSTITUTE(A2,9,4)*2+REPT(1,LEN(A2))-A2

跳转到最佳答案楼层

蝶·舞

9999不应该是0000吗？

丢丢表格

蝶·舞 发表于 2015-7-1 11:21
9999不应该是0000吗？

蝶老师好
9999  的 是 0000 ，所以就是 0 。
也就是 把 0000 转化为数值，结果就是 0 。
这里表达的是数值，并不是文本。

丢丢表格

蝶·舞 发表于 2015-7-1 11:21
9999不应该是0000吗？

此题的常规解法是：
=--MID(SUM(MOD((0&MID(A2,ROW($1:$15),1))+1,10)*10^-ROW($1:$15))&10,3,LEN(A2))
公式字数为 77 字， 远远大于 41 字的要求，这不是我想要的公式。

蝶·舞

常规解法有BUG

心正意诚身修

=SUM(RIGHT((MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+1))*(10^(LEN(A2)-ROW(INDIRECT("1:"&LEN(A2)))))) 我的方法.96個字符..哈哈哈.還是等高手來做吧.

丢丢表格

蝶·舞 发表于 2015-7-1 12:32
常规解法有BUG

把  LEFT 改成 MID 就行了
=--MID(SUM(MOD((0&MID(A2,ROW($1:$15),1))+1,10)*10^-ROW($1:$15))&10,3,LEN(A2))

怪了，LEFT 不行， MID 就可以了呢 ？？

丢丢表格

心正意诚身修 发表于 2015-7-1 12:57
=SUM(RIGHT((MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+1))*(10^(LEN(A2)-ROW(INDIRECT("1:"&LEN(A2)))))) 我 ...

身修 老师
       是闯关题， 其实不难，只是脑筋弯一下 就有了。

dachairen

=--RIGHT(SUBSTITUTE(REPT(1,15)+SUBSTITUTE(A2,9,19),30,0),LEN(A2))
41个字符太难了

丢丢表格

dachairen 发表于 2015-7-1 13:19
=--RIGHT(SUBSTITUTE(REPT(1,15)+SUBSTITUTE(A2,9,19),30,0),LEN(A2))
41个字符太难了

当 A 列 值为 123499566699  时，结果不正确。