[已解决]能把三维数组的值直接赋值给单元格吗？

mfk1288

Sub tt()
Dim arr( 1 To 10, 1 To 10)
Sheet1.Select
    For i = 1 To 10
        For j = 1 To 10
            arr( i, j) = Cells(i, j)
        Next
    Next
    Sheet2.Range("A1:J10") = arr
End Sub

以上的代码很简单，相信大家都以看明白。最终就是把数组直接赋值给单元格。现在如果改为三维数组
Sub tt()
Dim arr(1 To 10, 1 To 10, 1 To 10)
Sheet1.Select
    For i = 1 To 10
        For j = 1 To 10
            arr(i, i, j) = Cells(i, j)
        Next
    Next
    for i=1 to 10
Sheets(i+1).Range("A1:J10") = ????
next
End Sub

现在就是请问????能否象第一段代码一样。一句就可以把arr(1,1,1)到arr(1,10,10)直接赋值给表的Range("A1:J10") （我循环10次，就直接赋值给10个表的Range("A1:J10") ）

最佳答案

月排行榜 / 总排行榜

香川群子

2014-6-27 15:10

mfk1288 发表于 2014-6-26 17:42
求解，求答案啊！

答案不是早就明确了……

① 除了一维数组和二维数组以外，都不能直接把数组内容直接输出到工作表单元格。

原因很简单，因为工作表单元格区域本身就是二维数组结构，
所以可以直接把单元格区域一次性读入VBA内存数组、如： arr= Range("A1:C5")
或直接把VBA内存数组结果输出到单元格区域，如：Range("A1:C5") = arr


而一维数组视作二维数组的特殊形态、仅可作为 单行多列单元格区域的输出。
如 ：
arr = Array(1, 2, 3, 4)
[a1:d1] = arr

除此以外都不可行。


② 一维数组的补充说明：
单元格区域的单行读入数组时，得到1行n列的二维数组，而不是一维数组。形式如： arr(1, 1) to arr(1, n)
单元格区域的单列读入数组时，得到m行1列的二维数组，而不是一维数组。形式如： arr(1, 1) to arr(m, 1)

上述二维数组，可以通过 WorksheetFunction.Transpose()来转换为一维数组。

但是VBA中认为一维数组本质上相当于单行多列的二维数组，
所以一维数组使用WorksheetFunction.Transpose()来转换时，只能交替得到多行单列的二维数组和单行多列的一维数组。

即：
Sub test1()
    arr = [a1:a4] '从工作表多行单列得到一个二维数组
    brr = WorksheetFunction.Transpose(arr) '转换得到一维数组 (实际上相当于单行多列的二维数组)
    crr = WorksheetFunction.Transpose(brr) '再次转换得到多行单列的二维数组
    drr = WorksheetFunction.Transpose(crr) '转换得到一维数组 (实际上相当于单行多列的二维数组)
End Sub

Sub test2()
    arr = [a1:d1] '从工作表单行多列得到一个二维数组
    brr = WorksheetFunction.Transpose(arr) '转换得到多行单列的二维数组
    crr = WorksheetFunction.Transpose(brr) '再次转换得到一维数组 (实际上相当于单行多列的二维数组)
    drr = WorksheetFunction.Transpose(crr) '转换得到多行单列的二维数组
End Sub


因此，结论如下：
一维数组可作为单行多列区域直接输出到工作表单行。(一维数组事实上被默认为等效于单行多列的二维数组。)
如需输出到多行单列的区域，则必须使用 WorksheetFunction.Transpose(arr) 转换为二维数组、然后再输出到工作表。


③ 三维及以上的数组 无法直接输出到工作表区域。

只能通过For……Next循环进行逐个赋值。

…………
为提高输出效率，可以采取以下方法：
方法-1：
1. 定义临时二维数组 arr(1 to m, 1 to n)
2. 要输出部分内容、通过VBA内的For循环赋值到临时二维数组
3. 把临时二维数组结果输出到工作表

方法-2：
一开始就不要定义三维数组
但为了快速高效或理解方便，可以采取使用嵌套数组的方法。

代码例子：

1. Sub test1()
   
2.     Dim arr(1 To 3, 1 To 5, 1 To 10) '定义多维数组
   
3.    
   
4.     For i = 1 To 3
   
5.         For j = 1 To 5
   
6.             For k = 1 To 10
   
7.                 m = m + 1
   
8.                 arr(i, j, k) = m
   
9.             Next
   
10.         Next
    
11.     Next
    
12.     '以上为三维数组赋值
    
13. 
    
14. '    Cells.Clear
    
15.     For i = 1 To 3
    
16.         For j = 1 To 5
    
17.             For k = 1 To 10
    
18.                 Cells((i - 1) * 6 + 1 + j, k) = arr(i, j, k) '循环逐个输出
    
19.             Next
    
20.         Next
    
21.     Next
    
22. End Sub
    
23. 
    
24. Sub test2()
    
25.     Dim arr(1 To 3, 1 To 5, 1 To 10) '定义多维数组arr
    
26.     
    
27.     For i = 1 To 3
    
28.         For j = 1 To 5
    
29.             For k = 1 To 10
    
30.                 m = m + 1
    
31.                 arr(i, j, k) = m
    
32.             Next
    
33.         Next
    
34.     Next
    
35.     '以上为三维数组赋值
    
36. 
    
37. '    Cells.Clear
    
38.     Dim brr(1 To 5, 1 To 10) '定义一个输出用的临时二维数组brr
    
39.     For i = 1 To 3
    
40. '        Erase brr
    
41.         For j = 1 To 5
    
42.             For k = 1 To 10
    
43.                 brr(j, k) = arr(i, j, k) '把三维数组中内容转移到临时二维数组中
    
44.             Next
    
45.         Next
    
46.         [a1].Offset((i - 1) * 6 + 1).Resize(5, 10) = brr '多阶段一次性输出结果到工作表
    
47.     Next
    
48. End Sub
    
49. 
    
50. 
    
51. Sub test3()
    
52.     Dim crr(1 To 3) '定义嵌套数组
    
53.     Dim trr(1 To 5, 1 To 10) '定义可输出结果的二维数组
    
54.     For i = 1 To 3
    
55.         crr(i) = trr '完成嵌套数组的定义
    
56.     Next
    
57.    
    
58.     For i = 1 To 3
    
59.         For j = 1 To 5
    
60.             For k = 1 To 10
    
61.                 n = n + 1
    
62.                 crr(i)(j, k) = n
    
63.             Next
    
64.         Next
    
65.     Next
    
66.     '以上为嵌套数组赋值 实际用法和三维数组也很类似的
    
67. 
    
68. '    Cells.Clear
    
69.     For i = 1 To 3
    
70.         [a1].Offset((i - 1) * 6 + 1).Resize(5, 10) = crr(i)
    
71.         '这样就可以把嵌套的二维数组部分内容直接输出了。
    
72.     Next
    
73. End Sub
    

复制代码

呵呵。

跳转到最佳答案楼层

xdragon

三维数组不能像一维或二维数组那样一次性赋值给单元格的，不过你的这个目的貌似不用三维数组吧。
直接
for i=1 to 10
sheets(i).range("A1:J10")=二维数组
next
这样不是更简单点吗？

hwc2ycy

用三维多难理解。
就用2楼的方法就成了。

mfk1288

hwc2ycy 发表于 2014-6-26 16:34
用三维多难理解。
就用2楼的方法就成了。

我举例只是用一个简单的二维数组与三维数组，实际上的三维数组arr(100,1000,16),我已经生成了一个三维数组，如何把100个1000行*16列的数据填入100个表里，用循环是可以达到最终的结果，但是想能不能直接写入赋值，而不需要循环才能达到目的。

mfk1288

求解，求答案啊！

香川群子

mfk1288 发表于 2014-6-26 17:42
求解，求答案啊！

答案不是早就明确了……

① 除了一维数组和二维数组以外，都不能直接把数组内容直接输出到工作表单元格。

原因很简单，因为工作表单元格区域本身就是二维数组结构，
所以可以直接把单元格区域一次性读入VBA内存数组、如： arr= Range("A1:C5")
或直接把VBA内存数组结果输出到单元格区域，如：Range("A1:C5") = arr


而一维数组视作二维数组的特殊形态、仅可作为 单行多列单元格区域的输出。
如 ：
arr = Array(1, 2, 3, 4)
[a1:d1] = arr

除此以外都不可行。


② 一维数组的补充说明：
单元格区域的单行读入数组时，得到1行n列的二维数组，而不是一维数组。形式如： arr(1, 1) to arr(1, n)
单元格区域的单列读入数组时，得到m行1列的二维数组，而不是一维数组。形式如： arr(1, 1) to arr(m, 1)

上述二维数组，可以通过 WorksheetFunction.Transpose()来转换为一维数组。

但是VBA中认为一维数组本质上相当于单行多列的二维数组，
所以一维数组使用WorksheetFunction.Transpose()来转换时，只能交替得到多行单列的二维数组和单行多列的一维数组。

即：
Sub test1()
    arr = [a1:a4] '从工作表多行单列得到一个二维数组
    brr = WorksheetFunction.Transpose(arr) '转换得到一维数组 (实际上相当于单行多列的二维数组)
    crr = WorksheetFunction.Transpose(brr) '再次转换得到多行单列的二维数组
    drr = WorksheetFunction.Transpose(crr) '转换得到一维数组 (实际上相当于单行多列的二维数组)
End Sub

Sub test2()
    arr = [a1:d1] '从工作表单行多列得到一个二维数组
    brr = WorksheetFunction.Transpose(arr) '转换得到多行单列的二维数组
    crr = WorksheetFunction.Transpose(brr) '再次转换得到一维数组 (实际上相当于单行多列的二维数组)
    drr = WorksheetFunction.Transpose(crr) '转换得到多行单列的二维数组
End Sub


因此，结论如下：
一维数组可作为单行多列区域直接输出到工作表单行。(一维数组事实上被默认为等效于单行多列的二维数组。)
如需输出到多行单列的区域，则必须使用 WorksheetFunction.Transpose(arr) 转换为二维数组、然后再输出到工作表。


③ 三维及以上的数组 无法直接输出到工作表区域。

只能通过For……Next循环进行逐个赋值。

…………
为提高输出效率，可以采取以下方法：
方法-1：
1. 定义临时二维数组 arr(1 to m, 1 to n)
2. 要输出部分内容、通过VBA内的For循环赋值到临时二维数组
3. 把临时二维数组结果输出到工作表

方法-2：
一开始就不要定义三维数组
但为了快速高效或理解方便，可以采取使用嵌套数组的方法。

代码例子：

1. Sub test1()
   
2.     Dim arr(1 To 3, 1 To 5, 1 To 10) '定义多维数组
   
3.    
   
4.     For i = 1 To 3
   
5.         For j = 1 To 5
   
6.             For k = 1 To 10
   
7.                 m = m + 1
   
8.                 arr(i, j, k) = m
   
9.             Next
   
10.         Next
    
11.     Next
    
12.     '以上为三维数组赋值
    
13. 
    
14. '    Cells.Clear
    
15.     For i = 1 To 3
    
16.         For j = 1 To 5
    
17.             For k = 1 To 10
    
18.                 Cells((i - 1) * 6 + 1 + j, k) = arr(i, j, k) '循环逐个输出
    
19.             Next
    
20.         Next
    
21.     Next
    
22. End Sub
    
23. 
    
24. Sub test2()
    
25.     Dim arr(1 To 3, 1 To 5, 1 To 10) '定义多维数组arr
    
26.     
    
27.     For i = 1 To 3
    
28.         For j = 1 To 5
    
29.             For k = 1 To 10
    
30.                 m = m + 1
    
31.                 arr(i, j, k) = m
    
32.             Next
    
33.         Next
    
34.     Next
    
35.     '以上为三维数组赋值
    
36. 
    
37. '    Cells.Clear
    
38.     Dim brr(1 To 5, 1 To 10) '定义一个输出用的临时二维数组brr
    
39.     For i = 1 To 3
    
40. '        Erase brr
    
41.         For j = 1 To 5
    
42.             For k = 1 To 10
    
43.                 brr(j, k) = arr(i, j, k) '把三维数组中内容转移到临时二维数组中
    
44.             Next
    
45.         Next
    
46.         [a1].Offset((i - 1) * 6 + 1).Resize(5, 10) = brr '多阶段一次性输出结果到工作表
    
47.     Next
    
48. End Sub
    
49. 
    
50. 
    
51. Sub test3()
    
52.     Dim crr(1 To 3) '定义嵌套数组
    
53.     Dim trr(1 To 5, 1 To 10) '定义可输出结果的二维数组
    
54.     For i = 1 To 3
    
55.         crr(i) = trr '完成嵌套数组的定义
    
56.     Next
    
57.    
    
58.     For i = 1 To 3
    
59.         For j = 1 To 5
    
60.             For k = 1 To 10
    
61.                 n = n + 1
    
62.                 crr(i)(j, k) = n
    
63.             Next
    
64.         Next
    
65.     Next
    
66.     '以上为嵌套数组赋值 实际用法和三维数组也很类似的
    
67. 
    
68. '    Cells.Clear
    
69.     For i = 1 To 3
    
70.         [a1].Offset((i - 1) * 6 + 1).Resize(5, 10) = crr(i)
    
71.         '这样就可以把嵌套的二维数组部分内容直接输出了。
    
72.     Next
    
73. End Sub
    

复制代码

呵呵。

香川群子

显然嵌套数组的方法最好。

推荐楼主今后就这么用吧。没必要使用三维数组的。

laoau138

香川群子 发表于 2014-6-27 15:10
答案不是早就明确了……

① 除了一维数组和二维数组以外，都不能直接把数组内容直接输出到工作表单元格 ...

解析好专业，你可以去写书，准备发行了