[已解决]如何可以去除单元格中某特定字符之后的数字保留其它?

avallon · 发表于 2013-12-23 16:39

初来炸到, 请教大虾一个问题.

有列单元格内部数据都是数字间用"."分隔, 例如"5.4.23.68", 只将最后一个小数点后的数字"68"去掉,保留所有前面的数字为"5.4.23"?

因为每个小数点之间的数字是随机的, 可能是一位数,也可能是两位三位数, 所以用LEFT不合适.

请帮忙看看

最佳答案

月排行榜 / 总排行榜

chensir

2013-12-23 17:09

本帖最后由 chensir 于 2013-12-23 17:13 编辑

=LEFT(A1,FIND("/",SUBSTITUTE(A1,".","/",LEN(A1)-LEN(SUBSTITUTE(A1,".",))))-1)
此公式用于无论多少小数点，去除最后一个小数点及后面字符

跳转到最佳答案楼层

1091126096 · 发表于 2013-12-23 16:43

本帖最后由 1091126096 于 2013-12-23 17:18 编辑

最后一个小数点去掉，=MID(A1,1,FIND("A",SUBSTITUTE(A1,".","A",LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-1)
如果点保留，改为 =MID(A1,1,FIND("A",SUBSTITUTE(A1,".","A",LEN(A1)-LEN(SUBSTITUTE(A1,".","")))))

baksy · 发表于 2013-12-23 16:49

如果最后小数点后面都是两位数的话可以以下公式解决
=LEFT(A1,LEN(A1)-3)

wayy · 发表于 2013-12-23 16:59

=LEFT(A1,FIND("@",SUBSTITUTE(A1,".","@",3))-1)

复制代码

E路人 · 发表于 2013-12-23 17:02

本帖最后由 E路人于 2013-12-23 17:11 编辑

=LEFT(A1,LOOKUP(1,0/(MID(A1,ROW(1:99),1)="."),ROW(1:99)-1))

复制代码

xdragon · 发表于 2013-12-23 17:03

本帖最后由 xdragon 于 2013-12-23 17:04 编辑

=LEFT(A1,MAX(IF(MID(A1,ROW($1:$99),1)=".",ROW($1:$99)))-1)

复制代码

Ctrl+Shift+Enter

chensir · 发表于 2013-12-23 17:09

这个最佳答案由 chensir 给出，感谢 chensir 的回答。

单击隐藏图章

本帖最后由 chensir 于 2013-12-23 17:13 编辑

=LEFT(A1,FIND("/",SUBSTITUTE(A1,".","/",LEN(A1)-LEN(SUBSTITUTE(A1,".",))))-1)
此公式用于无论多少小数点，去除最后一个小数点及后面字符

tgydslr · 发表于 2013-12-23 18:08

这个无论咋样都可以，

=LEFT(A1,FIND("@",SUBSTITUTE(A1,".","@",LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-1)

复制代码

三键结束

爱疯 · 发表于 2013-12-23 22:14

替换*.*.*.*为*.*.*

行么，没法实验(>_<)

avallon · 发表于 2013-12-24 08:43

谢谢, 楼上几位的方法试验可用,非常感谢!

		自动登录	找回密码
密码			注册

[已解决]如何可以去除单元格中某特定字符之后的数字保留其它?

相关帖子

点评

评分

评分