第九期【每周一测】查找函数 答题秀

展翅

为方便大家讨论和分享，【每周一测】提供答题帖供大家跟帖交流。

欢迎各位跟帖分享奇招妙想。论坛会根据答题内容给予一定的金币或经验奖励。
第九期下载地址：http://www.excelpx.com/thread-309294-1-1.html

风林火山

1.1

1. =VLOOKUP($F24,$B23:$D36,COLUMN(B1),FALSE)

复制代码

1.2

1. =VLOOKUP(C47,{1,"金牌";2,"银牌";3,"铜牌";4,"未得奖"},2)

复制代码

2.1

1. =VLOOKUP(A18,TRANSPOSE($A$12:$G$14),2,)

复制代码

2.2

1. =VLOOKUP(A18,TRANSPOSE($A$12:$G$14),3,)

复制代码

3

1. =VLOOKUP(E16&F16,IF({1,0},A16:A27&B16:B27,C16:C27),2,)

复制代码

4.1

1. =VLOOKUP($F15&" ",$B$14:$D$27,COLUMN(B1),)

复制代码

空格复制B14单元格内容后面的，不显示但可以涂黑的字符
4.2

1. =VLOOKUP(REPT("0",3-LEN(F19))&F19,$A$14:$D$27,3,)

复制代码

5

1. =VLOOKUP(E19,IF({0,1},A19:A27,B19:B27),2,)

复制代码

1. =INDEX(A19:A27,MATCH(E19,B19:B27,))

复制代码

1. =OFFSET(A18,MATCH(E19,B19:B27,),)

复制代码

1.   =INDIRECT("A"&MAX(IF(B19:B27=E19,ROW(B19:B27))))

复制代码

1. =LOOKUP(0,0/(E19=B19:B27),A19:A27)

复制代码

1. =LOOKUP(1,--(B19:B27=E19),A19:A27)

复制代码

美斯特邦威

终于出题了
一，1，=VLOOKUP($F24,$B$23:$D$36,COLUMN(B1),) 右拉
      2，来个不一样的  =TEXT(C47,"[=1]金牌;[=2]银牌;")&TEXT(C47,"[=3]铜牌;[>3]未得奖;")
二  ，    =HLOOKUP($A18,$A$12:$G$14,2,)     =HLOOKUP($A18,$A$12:$G$14,3,)
三  =VLOOKUP(E16&F16,CHOOSE({1,2},A16:A27&B16:B27,C16:C27),2,)
四 1 ，=VLOOKUP($F15&"*",$B$14:$D$27,COLUMN(B1),) 右拉
    2  ，=VLOOKUP(TEXT(F19,"000"),$A$14:$C$27,3,)
五    =LOOKUP(,0/(B19:B27=E19),A19:A27)  先来一种方法，剩下的留给大家补充

huangcaiguang

火山喷发了，凑个热闹：
1.1
=DGET(B22:D36,2,F23:F24)
=LOOKUP(,0/($B23:$B36=$F24),C23:C24)
有几大经典的交叉取值模型可以参照：
http://www.excelpx.com/thread-308205-1-1.html
1.2
=IF(C47>3,"未得奖",TEXT(C47-2,"铜牌;金牌;银牌"))
=IF(C47>3,"未得奖",MID("金银铜",C47,1)&"牌")
=IF(C47>3,"未得奖",INDEX({"金","银","铜"},C47)&"牌")
=IF(C47>3,"未得奖",CHOOSE(C47,"金","银","铜")&"牌")
要不搞条件格式也行。。。
2
C18=SUMPRODUCT(n(B$12:G$12=A18),B$13:G$13)
C18=OFFSET(A$13,,MATCH(A18,B$12:G$12))下拉
C18=INDEX(B$13:G$13,MATCH(A18,B$12:G$12))
C18 =SUMIF($12:$12,A18,$13:$13)
C18=HLOOKUP(A18,$12:$14,2,)
C18{=MAX((A18=B$12:G$12)*B$13:G$13)}
F18=SUMPRODUCT(n(B$12:G$12=A18),B$14:G$14)
F18=OFFSET(A$14,,MATCH(A18,B$12:G$12))下拉
F18=INDEX(B$14:G$14,MATCH(A18,B$12:G$12))
F18=SUMIF($12:$12,A18,$14:$14)
F18 =HLOOKUP(A18,$12:$14,3,)
F18{=MAX((A18=B$12:G$12)*B$14:G$14)}
4.2
G19{=INDEX(C$14:C$27,MATCH(F19,(A$14:A$27)*1,))}   
第5题怎么感觉和第一题太像，也用DGET()  
=DGET(A18:B27,1,E18:E19)

ppp710715

1.2
=IF(C47>3,"未得奖",LOOKUP(C47,{1,2,3},{"金牌","银牌","铜牌"}))

ppp710715

3
数组公式：
=VLOOKUP(E16&F16,IF({1,0},$A$16:$A$27&$B$16:$B$27,$C$16:$C$27),2,)

qq1194660920

1.1:=VLOOKUP($F24,$B$23:$D$36,COLUMN(B1),)
1.2:=VLOOKUP(SMALL($C$47:$C$56,ROW(A1)),IF({1,0},$C$47:$C$56,A$47:A$56),2,)下拉右拉重排序了，不知道有没理解错。
2.1=VLOOKUP(A18,TRANSPOSE($B$12:$G$14),2,)
2.2=VLOOKUP(A18,TRANSPOSE($B$12:$G$14),3,)
3.1=VLOOKUP(E16&F16,IF({1,0},A16:A27&B16:B27,$C$16:$C$27),2,)
4.1=VLOOKUP($F15&" ",$B$14:$D$27,COLUMN(B1),)
4.2=VLOOKUP(TEXT(F19,"000"),IF({1,0},$A$14:$A$27,$C$14:$C$27),2,)
5.1=LOOKUP(1,0/(B19:B27=E19),A19:A27)

xdragon

第一题
1、G24=VLOOKUP(TEXT($F$14,"000"),$A$23:$D$36,MATCH(G$23,$A$22:$D$22,),)  右拉
2、我怎么觉得函数已经做好了。。。-。-
最多稍微改动下，节约2个字符=IF(C56<=3,CHOOSE(C56,"金","银","铜")&"牌","未得奖")

第二题
C18=HLOOKUP($A18,$A$12:$G$14,2,)下拉填充
F18=HLOOKUP($A18,$A$12:$G$14,3,)下拉填充

第三题
G16=VLOOKUP(E16&F16,IF({1,0},A16:A27&B16:B27,C16:C27),2,) Ctrl+Shift+Enter
PS：不知道为什么，小编设置的下拉菜单有错误，哈哈

第四题
1、G15=VLOOKUP($F15&"?",$B$14:$D$27,COLUMN(B1),) 右拉
2、G19=VLOOKUP(TEXT(F19,"000"),$A$14:$D$27,3,) 下拉

第五题
=INDEX(A19:A27,MATCH(E19,B19:B27,))

剑灵

第一题：
1、=VLOOKUP($F24,$B$23:$D$36,COLUMN(B1),)，右拉
2、=LOOKUP(C47,{1,2,3,4},{"金牌","银牌","铜牌","未得奖"})，下拉

第二题：
1、=HLOOKUP($A18,$B$12:$G$14,COLUMN(B1),)，下拉
2、=HLOOKUP($A18,$B$12:$G$14,COLUMN(C1),)，下拉

第三题
1、=SUMPRODUCT(($A$16:$A$27=E16)*($B$16:$B$27=F16)*(C16:C27))

第四题
1、=VLOOKUP($F15&" ",$B$14:$D$27,COLUMN(B1),)，右拉
2、=VLOOKUP(TEXT(F20,"000"),$A$14:$C$27,COLUMN(C1),)，下拉

第五题
公式1：=INDEX(A19:A27,MATCH(E19,$B$19:$B$27,),)
公式2：=VLOOKUP(E19,IF({1,0},$B$19:$B$27,$A$19:$A$27),2,)
公式3：=VLOOKUP(E19,CHOOSE({1,2},B19:B27,A19:A27),COLUMN(B1),)

hcjh2013

第一题，1.=VLOOKUP($F$24,$B$23:$D$36,COLUMN()-5,0)
            2.=IF(C47=1,"金牌",IF(C47=2,"银牌",IF(C47=3,"铜牌","未得奖")))
刚学的，不要见笑