【函数初级201203班】第五讲D组作业上交帖【已开贴】

水吉果果

1、本贴是回贴仅作者可见，直接跟贴回复即可。
2、上交时直接贴公式，只上传附件的不予批改
请各位童鞋使用代表功能,就是一个<>的按钮里输入公式,效果如

1. =sum(a:a)

复制代码

直接回复答案者必须注明【函初201203班】-组学号-论坛ID,如【函初201203班]- D01:yanyupingsheng;
3、截止时间2013年1月10日20：00
4、请误重复占楼，非本班同学跟贴回复者扣分

MYHERE131

作业一：
  法一：=VLOOKUP($B$10,IF({1,0},附表1!$H$2:$H$19,INDIRECT("附表1!"&INDEX({"A","B","C","D","E","F","G"},MATCH(C$9,附表1!$A$1:$G$1,0))&"2:"&INDEX({"A","B","C","D","E","F","G"},MATCH(C$9,附表1!$A$1:$G$1,0))&"19")),2,0)
  法二：=HLOOKUP(C$9,附表1!$A$1:$H$19,MATCH(作业!$B$10,附表1!$H$1:$H$19,0),0)
  法三：=INDEX(附表1!$A$1:$G$19,MATCH($B$10,附表1!$H$1:$H$19,0),MATCH(作业!C$9,附表1!$A$1:$G$1,0))


作业二：
  姓名处：=INDEX(附表1!$H:$H,SMALL(IF(ISNUMBER(FIND("李",附表1!$H$2:$H$19)),ROW($2:$19),99),ROW(A1)))&""
  引用成绩：=IF(ISNA(HLOOKUP(D$19,附表1!$A$1:$H$19,MATCH($C20,附表1!$H$1:$H$19,0),0)),"",HLOOKUP(D$19,附表1!$A$1:$H$19,MATCH($C20,附表1!$H$1:$H$19,0),0))

作业三：
法一：=INDEX($A$36:$A$43,COLUMN()-2)
  法二：=INDIRECT("a"&COLUMN()+33)
  法三：=TRANSPOSE($A$36:$A$43)

hwc2ycy

第一题
三键

1. =VLOOKUP(C$9,TRANSPOSE(附表1!$A$1:$G$19),MATCH(作业!$B$10,附表1!$H$1:$H$19,),)

复制代码

1. =VLOOKUP($B$10,CHOOSE(COLUMN($A$1:$H$1),附表1!$H$1:$H$19,附表1!$A$1:$A$19,附表1!$B$1:$B$19,附表1!$C$1:$C$19,附表1!$D$1:$D$19,附表1!$E$1:$E$19,附表1!$F$1:$F$19,附表1!$G$1:$G$19),MATCH(C$9,附表1!$A$1:$G$1,)+1,0)

复制代码

1. =INDEX(附表1!$A$2:$G$19,MATCH(作业!$B$10,附表1!$H$2:$H$19,),MATCH(作业!C$9,附表1!$A$1:$G$1,))

复制代码

1. =HLOOKUP(C$9,附表1!$A$1:$G$19,MATCH(作业!$B$10,附表1!$H$1:$H$19,),)

复制代码

1. =OFFSET(附表1!$A$1,MATCH(作业!$B$10,附表1!$H$2:$H$19,),MATCH(作业!C$9,附表1!$A$1:$G$1,)-1)

复制代码

1. =INDIRECT("附表1!r"&MATCH($B$10,附表1!$H$1:$H$19,)&"c"&MATCH(C$9,附表1!$A$1:$G$1,),FALSE)

复制代码

1. =OFFSET(附表1!$A$1,LOOKUP(0,0/(附表1!$H$1:$H$19=$B$10),ROW($A$1:$A$19))-1,LOOKUP(1,1/(附表1!$A$1:$G$1=作业!C$9),COLUMN($A$1:$G$1)-1))

复制代码

第二题

1. =IFERROR(INDEX(附表1!$A$2:$H$19,SMALL(IF(LEFT(附表1!$H$2:$H$19,1)="李",ROW($A$1:$A$18),4^8),$B20),MATCH(作业!C$19,附表1!$A$1:$H$1,)),"")

复制代码

1. =INDEX(附表1!$A:$H,SMALL(IF(LEFT(附表1!$H$2:$H$19,1)="李",ROW($A$1:$A$18)+1,4^8),$B20),MATCH(C$19,附表1!$A$1:$H$1,))&""

复制代码

1. =INDIRECT("附表1!R"&SMALL(IF(LEFT(附表1!$H$1:$H$19,1)="李",ROW($A$1:$A$18),20),$B20)&"c"&MATCH(C$19,附表1!$1:$1,),FALSE)&""

复制代码

作业三

1. =INDEX($A$36:$A$43,--C33,)

复制代码

1. =VLOOKUP(--C33,IF({1,0},ROW($A$1:$A$8),$A$36:$A$43),2,)

复制代码

1. =OFFSET($A$35,--C33,)

复制代码

再就业

【函初201203班]- D23-再就业：
作业1:

1. =VLOOKUP($B$10,CHOOSE({1,2,3,4,5,6,7,8},附表1!$H:$H,附表1!$A:$A,附表1!$B:$B,附表1!$C:$C,附表1!$D:$D,附表1!$E:$E,附表1!$F:$F,附表1!$G:$G),MATCH(作业!C9,附表1!$A$1:$G$1,)+1,0)
   
2. =HLOOKUP(C9,附表1!$A$1:$G$19,MATCH($B10,附表1!$H$1:$H$19,),0)
   
3. =INDEX(附表1!$A$2:$G$19,MATCH($B10,附表1!$H$2:$H$19,0),MATCH(作业!C$9,附表1!$A$1:$G$1,0))

复制代码

作业2：

1. 做2个辅助列，第1个辅助列的公式：=COUNTIF(H2,"李*")，第2个辅助列的公式：=IF(J2>0,ROW(),4^8)
   
2. 姓名用这个公式取得=INDEX(附表1!H:H,SMALL(附表1!K:K,ROW(A1)))&""
   
3. 后边的数学等成绩用=HLOOKUP(D$19,附表1!$A$1:$G$19,MATCH($C20,附表1!$H$1:$H$19,),0)这个公式完成。

复制代码

作业3：

1. =INDEX($A$36:$A$43,COLUMN(A1),1)
   
2. =OFFSET($A35,COLUMN(A1),0)
   
3. =INDIRECT("A"&(COLUMN(A1)+35))
   
4. =TRANSPOSE($A$36:$A$43)

复制代码

xsl343866865

[函初201203班]-D24:xsl343866865
作业一:

1. {=VLOOKUP(C9,TRANSPOSE(附表1!$A:$H),MATCH($B10,附表1!$H:$H,),)}
   
2. =HLOOKUP(C9,附表1!$A:$G,MATCH($B10,附表1!$H$1:$H$19,),)
   
3. =INDEX(附表1!$A$1:$G$19,MATCH($B10,附表1!$H$1:$H$19,),MATCH(C9,附表1!$A$1:$G$1,))
   
4. =INDIRECT("附表1!"&"R"&MATCH($B10,附表1!$H:$H,)&"C"&MATCH(C9,附表1!$A$1:$G$1,),)
   
5. =OFFSET(附表1!$A$1,MATCH($B$10,附表1!$H$2:$H$19,),MATCH(C9,附表1!$A$1:$G$1,)-1)

复制代码

作业二:

1. {=IFERROR(HLOOKUP(C$21,附表1!$A$1:$H$19,MATCH($B22&"李*",COUNTIF(INDIRECT("附表1!H$1:H"&ROW($1:$99)),"李*")&附表1!$H$1:$H$19,),),"")}
   
2. {=IFERROR(INDEX(附表1!$A$1:$H$19,MATCH($B22&"李*",COUNTIF(INDIRECT("附表1!H$1:H"&ROW($1:$99)),"李*")&附表1!$H$1:$H$19,),MATCH(C$21,附表1!$A$1:$H$1,)),"")}
   
3. {=IFERROR(OFFSET(附表1!$A$1,MATCH($B22&"李*",COUNTIF(INDIRECT("附表1!H$1:H"&ROW($1:$99)),"李*")&附表1!$H$1:$H$19,)-1,MATCH(C$21,附表1!$A$1:$H$1,)-1),"")}
   
4. {=IFERROR(INDIRECT("附表1!"&"R"&MATCH($B22&"李*",COUNTIF(INDIRECT("附表1!H$1:H"&ROW($1:$99)),"李*")&附表1!$H$1:$H$19,)&"C"&MATCH(C$21,附表1!$A$1:$H$1,),),"")}

复制代码

作业三:

1. {=VLOOKUP(C35,IF({1,0},ROW($A:$A),$A$38:$A$45),2,)}
   
2. =INDEX($A$38:$A$45,C35,)
   
3. {=TRANSPOSE($A$38:$A$45)}
   
4. =INDIRECT("A"&ROW($A$37)+C35)
   
5. {=VLOOKUP(C35,CHOOSE({1,2},TRANSPOSE($C$35:$J$35),$A$38:$A$45),2,)}
   
6. =HLOOKUP($A$38,$A$38:$A$45,C35)
   

复制代码

yanyupingsheng

1. 作业一
   
2. 1、=INDEX(附表1!$A$1:$H$19,MATCH($B$10,附表1!$H$1:$H$19,),MATCH(作业!C$9,附表1!$A$1:$H$1,))
   
3. 2、=OFFSET(附表1!$A$1,MATCH(作业!$B$10,附表1!$H$2:$H$19,),MATCH(作业!C$9,附表1!$A$1:$G$1,)-1)
   
4. 3、=VLOOKUP($B$10,CHOOSE({1,2,3,4,5,6,7,8},附表1!$H$1:$H$19,附表1!$A$1:$A$19,附表1!$B$1:$B$19,附表1!$C$1:$C$19,附表1!$D$1:$D$19,附表1!$E$1:$E$19,附表1!$F$1:$F$19,附表1!$G$1:$G$19),MATCH(作业!C$9,附表1!$A$1:$G$1,)+1,0)
   
5. 作业二
   
6. =IF(ISERROR(INDEX(OFFSET(附表1!$A$2:$A$19,0,MATCH(C$19,附表1!$A$1:$H$1,)-1),SMALL(IF(LEFT(附表1!$H$2:$H$19,1)="李",ROW($1:$18)),ROW($A1)))),"",INDEX(OFFSET(附表1!$A$2:$A$19,0,MATCH(C$19,附表1!$A$1:$H$1,)-1),SMALL(IF(LEFT(附表1!$H$2:$H$19,1)="李",ROW($1:$18)),ROW($A1))))
   
7. 作业三
   
8. 1、=TRANSPOSE($A$36:$A$43)
   
9. 2、=OFFSET($A$35,COLUMN(A1),0)
   
10. 3、=INDEX($A$36:$A$43,COLUMN(A1),0)

复制代码

【函初201203班】- D01:yanyupingsheng

xiaox0124

1. =INDEX(附表1!$A$2:$G$19,MATCH(作业!$B$10,附表1!$H$2:$H$19,),MATCH(作业!C9,附表1!$A$1:$H$1,))

复制代码

1. =HLOOKUP(C$9,附表1!$A$1:$G$19,MATCH(作业!$B$10,附表1!$H$1:$H$19,),)

复制代码

1. =VLOOKUP($B$10,IF({1,0},附表1!$H$2:$H$19,INDEX(附表1!$A$2:$G$19,,MATCH(作业!C$9,附表1!$A$1:$G$1,))),2,)
   

复制代码

1. =INDEX(附表1!$A:$H,SMALL(IF((LEFT(附表1!$H$1:$H$19)="李"),ROW($1:$19),4^8),ROW(A1)),MATCH(C$20,附表1!$A$1:$H$1,))&""
   

复制代码

1. =INDEX($A$37:$A$44,C$34,1)
   
2. =OFFSET($A$37,C$34-1,0,1,1)
   
3. =INDIRECT(ADDRESS(36+C34,1))

复制代码

丫头加油站

【函初201203班]- D35:丫头加油站
作业一：

1. =SUMPRODUCT(MID(C11,ROW(INDIRECT("1:"&LEN(C11))),1)*1)

复制代码

作业二：

1. =LEFT(C16,LENB(C16)-LEN(C16))

复制代码

1. =RIGHT(C17,LENB(C17)-LEN(C17))

复制代码

作业三：

1. =DAY(EOMONTH(A22,0))

复制代码

1. =EDATE(A22,1)-A22

复制代码

1. =DAY(EOMONTH(A22,0))

复制代码

作业四：数组公式:

1. =SUM(IF(EXACT(A27,$B$33:$B$62),$C$33:$C$62))

复制代码

数组公式

1. :=SUM(IF(ISNUMBER(FIND("c",B33:B62)),C33:C62))

复制代码

1. =SUMPRODUCT((ISNUMBER(FIND("c",B33:B62)))*C33:C62)

复制代码

作业五：

1. =WEEKDAY(A33,2)

复制代码

1. =SUMPRODUCT(($D$33:$D$62=1)*$C$33:$C$62)

复制代码

wangjianff

作业一：
=INDEX(OFFSET(附表1!$A2:$A19,,MATCH(C9,附表1!$A1:$G1,)-1),MATCH($B10,附表1!$H2:$H19,))
=VLOOKUP($B10,CHOOSE({1,2},附表1!$H2:$H19,OFFSET(附表1!$A2:$A19,,MATCH(C9,附表1!$A1:$G1,)-1)),2,)
=HLOOKUP(C9,附表1!$A1:$G19,MATCH($B10,附表1!$H1:$H19,),)
作业二：
{=IFERROR(HLOOKUP(C$19,附表1!$A$1:$H$19,LARGE((LEFT(附表1!$H$2:$H$19,1)="李")*ROW($2:$19),ROW($A1)),),"")}
作业三：
=INDEX($A$36:$A$43,C$33)
=HLOOKUP($A$36,$A$36:$A$43,C33,)
=VLOOKUP(OFFSET($A$35,C$33,0),$A$36:$A$43,1,)
【函数初级201203班】-D31-wangjianff

stone1969

【函初201203班]- D03:stone1969(1109590007)
作业一
方法1 =INDEX(附表1!$A:$H,MATCH($B10,附表1!$H:$H,),MATCH(C$9,附表1!$A$1:$H$1,))
方法2 =VLOOKUP($B$10,IF({1,0},附表1!$H$2:$H$19,OFFSET(附表1!$A$2:$A$19,,MATCH(C$9,附表1!$A$1:$G$1,)-1)),2,)
方法3 =HLOOKUP(C$9,IF({1;0},附表1!$A$1:$H$1,OFFSET(附表1!$A$1:$H$1,MATCH($B$10,附表1!$H$2:$H$19,),)),2,)
作业二
=IFERROR(INDEX(OFFSET(附表1!$A$1:$A$19,,MATCH(C$19,附表1!$A$1:$H$1,)-1),SMALL(IF("李"=LEFT(附表1!$H$1:$H$19),ROW($1:$19),20),ROW(A1))),"")   按CTRL+shift+enter
作业三
方法1 =TRANSPOSE(A36:A43)   按CTRL+shift+enter

选中C34：J34   =TRANSPOSE(A36:A43)
输入完公式后按Ctrl + Shift + Enter  三键结束。

方法2 =INDEX($A$36:$A$43,COLUMN(A1))
方法3 =OFFSET($A$36,COLUMN(A1)-1,ROW(A1)-1)