[已解决]【急】如何通过循环执行目标单元格改变而锁定目标行？

WANGL2

为什么会提示此错误呢？【参数数错误或无效的属性赋值(错误 450)】， 请VBA高手帮忙修正如下代码，万分感谢：

程序想要实现的功能：从第4行至65536行，通过改变H, I列值，而实现对本行E~G单元格的锁定并保护。

Private Sub Worksheet_Change(ByVal Target As Range) '不能被触发
'Application.EnableEvents = True
    Dim x As Integer
    For x = 4 To 65536 Step 1
    If Target.Address = "$H$" & x And Target.Value <> "" Then
        
        Range("E" & x, "F" & x, "G" & x).Locked = True
        Protect "123456789"
        MsgBox "此笔报销已被财务审核，不能再修改。请开新记录，重新登记。谢谢！"
        
    If Target.Address = "$H$" & x And Target.Value = "" Then
   
        Unprotect "123456789"
        Range("E" & x, "F" & x, "G" & x).Locked = False
        
    If Target.Address = "$I$" & x And Target.Value <> "" Then
        
        Range("E" & x, "F" & x, "G" & x).Locked = True
        Protect "123456789"
        MsgBox "此笔报销已被财务审核，不能再修改。请开新记录，重新登记。谢谢！"
        
    If Target.Address = "$I$" & x And Target.Value = "" Then
   
        Unprotect "123456789"
        Range("E" & x, "F" & x, "G" & x).Locked = False
        
    Else
      
        Unprotect "123456789"
        Range("E" & x, "F" & x, "G" & x).Locked = False
            
    End If
    End If
    End If
    End If
    Next x
   
End Sub

最佳答案

月排行榜 / 总排行榜

zjdh

2012-10-30 19:37

Private Sub Worksheet_Change(ByVal Target As Range)
    If (Target.Column = 8 Or Target.Column = 9) And Target.Count = 1 And Target.Row > 3 Then
        Unprotect "123456789"
        x = Target.Row
        If Target.Value <> "" Then
            Range("E" & x & ":G" & x).Locked = True
            MsgBox "此笔报销已被财务审核，不能再修改。请开新记录，重新登记。谢谢！"
        End If
        For I = 4 To 5000
            If Cells(I, 8) <> "" Or Cells(I, 9) <> "" Then
                Range("E" & I & ":G" & I).Locked = True
            Else
                Range("E" & I & ":G" & I).Locked = False
            End If
        Next
        Protect "123456789"
    End If
End Sub

跳转到最佳答案楼层

wp8680

Range前面加上一个工作表对象试试？
比如：Sheets(1).Range("E" & x, "F" & x, "G" & x).Locked = True
      

WANGL2

wp8680 发表于 2012-10-30 17:28
Range前面加上一个工作表对象试试？
比如：Sheets(1).Range("E" & x, "F" & x, "G" & x).Locked = True
...

老师：非常感谢您的思路！但问题依然。我将代码简化了一下，请再帮分析一下。多谢！

Private Sub Worksheet_Change(ByVal Target As Range) '不能被触发
'Application.EnableEvents = True
    Dim x As Integer
    For x = 4 To 3004 Step 1
   
    If Target.Address = "$H$" & x And Target.Value <> "" Then
        
        Sheets(6).Range("E" & x, "F" & x, "G" & x).Locked = True
        Protect "123456789"
        MsgBox "此笔报销已被财务审核，不能再修改。请开新记录，重新登记。谢谢！"

    If Target.Address = "$I$" & x And Target.Value <> "" Then
        
        Sheets(6).Range("E" & x, "F" & x, "G" & x).Locked = True
        Protect "123456789"
        MsgBox "此笔报销已被财务审核，不能再修改。请开新记录，重新登记。谢谢！"
        
    Else
      
        Unprotect "123456789"
        Worksheets(6).Range("E" & x, "F" & x, "G" & x).Locked = False
            
    End If
    End If
    Next x
   
End Sub

zjdh

1. Worksheet_Change是工作表事件，不是工作簿事件，用不着添加工作表对象！
2. 你的宏好多地方有问题，并且也太罗嗦。

zjdh

Private Sub Worksheet_Change(ByVal Target As Range)
    If (Target.Column = 8 Or Target.Column = 9) And Target.Count = 1 And Target.Row > 3 Then
        Unprotect "123456789"
        x = Target.Row
        If Target.Value <> "" Then
            Range("E" & x & ":G" & x).Locked = True
            MsgBox "此笔报销已被财务审核，不能再修改。请开新记录，重新登记。谢谢！"
        End If
        For I = 4 To 5000
            If Cells(I, 8) <> "" Or Cells(I, 9) <> "" Then
                Range("E" & I & ":G" & I).Locked = True
            Else
                Range("E" & I & ":G" & I).Locked = False
            End If
        Next
        Protect "123456789"
    End If
End Sub

wp8680

Sheets(6).Range("E" & x, "F" & x, "G" & x).Locked = True
这个的单元格表达，换成
Sheets(6).Range("E" & x & ":G" & x).Locked = True
这种试试，反正你是要E?:G?这三个单元格的判断，因此用联合区域更合适。

wp8680

并结合五楼的试试。因为手上没有附件，我也没法试

WANGL2

wp8680 发表于 2012-10-30 19:44
Sheets(6).Range("E" & x, "F" & x, "G" & x).Locked = True
这个的单元格表达，换成
Sheets(6).Range(" ...

非常感谢您！老师。

WANGL2

zjdh 发表于 2012-10-30 18:32
1. Worksheet_Change是工作表事件，不是工作簿事件，用不着添加工作表对象！
2. 你的宏好多地方有问题，并 ...

分析一针见血，很欣赏！谢谢老师指点。

WANGL2

zjdh 发表于 2012-10-30 19:37
Private Sub Worksheet_Change(ByVal Target As Range)
    If (Target.Column = 8 Or Target.Column = 9) ...

老师的代码精妙无比，也顺利通过测试。非常感谢！相信这就是最佳了！！