获得文件名的几种方法之四：FileDialog对象

wbzxz · 发表于 2011-5-19 01:38

FileDialog对象真的很不错，可以让我们通过对话框获取文件名，那真是方便多啦，我也是初步接触这个对象，正好也属于获取文件名方法的一种，试着写了一个自定义函数，分享给大家，请大家指出我的不足，帮助我找出错误和问题，非常感谢大家

'本函数具有通过文件对话框选取文件，获得文件名的功能；
'本函数使用了Office应用程序中的FileDialog对象；
'本函数有一个可选参数，FileType，用来传递文件类型与扩展名，String类型；默认是显示所有类型文件；
'当在对话框点击取消按钮时，返回一个下标为0的数组；
Function getFilename(Optional FileType As String = "") As String()
'定义变量部分
Dim FD As FileDialog '定义FD变量，存放FileDialog对象
Dim vFst As Variant '定义vFst变量，用来在For each循环中临时存放每个被选择的文件名
Dim FileName() As String '定义一个动态数组，存放选取的文件名
Dim iCounter As Long '定义iCounter计数器，判断获得了几个文件名
'通过application对象的FileDialog属性获得一个FileDialog对象，msoFileDialogFilePicker常量代表打开的是“文件选取器”对话框
Set FD = Application.FileDialog(msoFileDialogFilePicker)
iCounter = 1 '计数器初始化
With FD
If FileType <> "" Then '对FileType参数进行判断（默认为空，如果不为空，说明用户传递进来了文件类型参数），看看用户是否传递进来文件类型参数
.Filters.Clear '利用FileDialog对象的Filters属性，返回一个FileDialogFilters对象，FileDialogFilters的clear方法是删除当前在文件对话框中应用的所有筛选器。
.Filters.Add FileType, "*." & FileType 'FileDialogFilters.Add 方法,在“文件”对话框的“文件类型”下拉列表框的筛选器列表中添加一个新的文件筛选器
End If
.AllowMultiSelect = True 'FileDialog对象的AllowMultiSelect属性设置为true，允许用户从文件对话框中选择多个文件
.InitialFileName = ThisWorkbook.Path '设置文件对话框中初始显示的路径是当前文件路径
'FileDialog对象的show方法显示文件对话框，并返回一个Long 类型的值，指示用户按下的是“操作”按钮 (-1) 还是“取消”按钮 (0)。
If .Show = -1 Then
'通过FileDialog对象的SelectedItems属性，返回FileDialogSelectedItems对象，这个对象中存放了通过文件对话框获得的所有文件名的集合
'通过for each 语句，遍历每个文件名
For Each vFst In FD.SelectedItems
ReDim Preserve FileName(1 To iCounter) '重新定义动态数组大小
FileName(iCounter) = vFst '给数组元素赋值
iCounter = iCounter + 1
Next
Else '如果按了取消按钮，就执行下面语句,生成一个下标为0的数组，元素值为空
ReDim Preserve FileName(0 To 0)
FileName(0) = ""
End If
getFilename = FileName '把获得的文件名数组赋值给函数名
FD.Filters.Clear '恢复筛选器到原始状态
Set FD = Nothing '清空FileDialog对象
End With
End Function

复制代码

源文件附上，内含一个简单的示例文件：

获取文件名的方法4-FileDialog对象(通过对话框获取文件名).rar (13.33 KB, 下载次数: 242)

兰色幻想 · 发表于 2011-5-19 07:36

支持一下

wbzxz · 发表于 2011-5-19 08:06

嘿嘿，师傅早上就是起的早。

业余爱好者 · 发表于 2011-5-20 10:47

谢分享

半个城市 · 发表于 2011-5-21 23:38

支持一下师兄，先收藏了，现在看不懂，以后肯定可以的{:1712:}

gdgzlyh · 发表于 2011-5-22 22:59

hhzjxss · 发表于 2011-5-23 16:53

下载学习一下！值得收藏！

excelcrazy · 发表于 2011-5-24 19:38

谢谢分享，我下载看看啊

jiangjane627 · 发表于 2011-5-30 11:50

收藏起来慢慢看

tayisha · 发表于 2011-5-30 15:27

分享下，呵呵

		自动登录	找回密码
密码			注册

[分享] 获得文件名的几种方法之四：FileDialog对象

评分