获取数据到列表框中的几种方法小结

stx1980710

【原创】

希望通过下面几种方法的介绍，对喜欢用列表框来显示数据的朋友有所帮助！

不足之处，恳请大家批评指正！

常见的显示数据的方法有以下四种： 200731614492226487.rar (19.57 KB, 下载次数: 217)

2011-6-25 13:15 上传

点击文件名下载附件

 

第一种：RowSource属性
         可以利用该属性将列表框直接与工作表上的一个单元格区域相链接。在该区域中的任何变化将会立即使列表框相应变化，但在列表框中的数据是只读的，你不能对列表框中的数据进行删除或增加操作。这种方法有一点较好的，就是可以设置列标题。

          利用该属性，还有以下四种方式可选择：

 A、直接用工作表区域

        Private Sub UserForm_Initialize()
  Dim Erow As Integer
     Erow = Worksheets("Columns").Range("A65536").End(xlUp).Row
 With Me.ListBox1
    .ColumnCount = 3
    .BackColor = &HFFFF00
    .ColumnHeads = True
    .ColumnWidths = "80,50,30"
     .RowSource = "Columns!A2:C" & Erow
    End With
End Sub

 

B、用单元格的地址

Private Sub UserForm_Initialize()
 Dim Erow As Integer
     Erow = Worksheets("Columns").Range("A65536").End(xlUp).Row
 With Me.ListBox1
    .ColumnCount = 3
    .BackColor = &HFFFF00
    .ColumnHeads = True
    .ColumnWidths = "80,50,30"
     .RowSource = Worksheets("Columns").Range("A2:C" & Erow).Address(External:=True)
 End With
End Sub
在这里要注意：External:=True 这个参数不可少，这个参数表示一个外部引用。如果缺少的话，除非窗体是在RowSource 属性中所指的工作表中显示，否则列表框就会显示空白！

C、用命名的单元格

Private Sub UserForm_Initialize()
    ActiveWorkbook.Names.Add Name:="ListValue", RefersToR1C1:= _
        "=OFFSET(Columns!R2C1,,,COUNTA(Columns!C1)-1,3)"
 With Me.ListBox1
    .ColumnCount = 3
    .BackColor = &HFFFF00
    .ColumnHeads = True
    .ColumnWidths = "80,50,30"
    .RowSource = "ListValue"

      另一种表示方法为：

    .RowSource = Range("ListValue").Address(External:=True)

End With
End Sub

stx1980710

第二种：List属性

可用 List 把值的完整的二维数组复制到列表框控件上

          利用该属性，还有以下二种方式可选择：

A、利用数组

 rivate Sub UserForm_Initialize()
  Dim Arr0
 Dim Erow As Integer
     Erow = Worksheets("Columns").Range("A65536").End(xlUp).Row
     Arr0 = Worksheets("Columns").Range("A2:C" & Erow)
 With Me.ListBox1
    .ColumnCount = 3
    .BackColor = &HFFFF00
    .ColumnWidths = "80,50,30"
    .List = Arr0
  End With
End Sub

B、用命名的单元格

Private Sub UserForm_Initialize()
    ActiveWorkbook.Names.Add Name:="ListValue", RefersToR1C1:= _
        "=OFFSET(Columns!R2C1,,,COUNTA(Columns!C1)-1,3)"
 With Me.ListBox1
    .ColumnCount = 3
    .BackColor = &HFFFF00
    .ColumnWidths = "80,50,30"
    .List = Range("ListValue").Value
End With
End Sub

stx1980710

第三种：Column属性

          此方法和List属性的区别在于，用column属性须进行一下行列转置

 Private Sub UserForm_Initialize()
 Dim Arr0
 Dim Erow As Integer
     Erow = Worksheets("Columns").Range("A65536").End(xlUp).Row
     Arr0 = Worksheets("Columns").Range("A2:C" & Erow)
 With Me.ListBox1
    .ColumnCount = 3
    .BackColor = &HFFFF00
    .ColumnWidths = "80,50,30"
    .Column = Application.WorksheetFunction.Transpose(Arr0)
End With
End Sub

stx1980710

第四种：AddItem方法

          对于单列的列表框，在列表中添加一项。对于多列的列表框，在列表中添加一行。

Private Sub UserForm_Initialize()
 Dim i As Integer
 Dim Arr0
 Dim Erow As Integer
     Erow = Worksheets("Columns").Range("A65536").End(xlUp).Row
     Arr0 = Worksheets("Columns").Range("A2:C" & Erow)
 With Me.ListBox1
    .ColumnCount = 3
    .BackColor = &HFFFF00
    .ColumnWidths = "80,50,30"
     For i = 1 To UBound(Arr0)
         .AddItem
         .List(i - 1, 0) = Arr0(i, 1)
         .List(i - 1, 1) = Arr0(i, 2)
         .List(i - 1, 2) = Arr0(i, 3)
     Next i
End With
End Sub

syq1945

[em01][em01][em01]

沧海之鱼

好贴啊，终于找到我想要的东西了。谢谢楼主。

沧海之鱼

楼主，我打开后 EXCEK 显示“此工作簿已丢失VBA项目、ActiveX控件以及其它任何与可编程序性相关的功能。”？是什么地方出问题了吗？

zsd5237

好好好！

joyark

好贴啊，终于找到我想要的东西了。谢谢楼主。

wwy_168

为何下载不了，是权限问题吗？