[已解决]如何用VBA进行双条件汇总？

一剑惊心

如何根据两个条件分别对产品进行汇总？

TX6uVIb8.zip (2.26 KB, 下载次数: 101)

2010-4-23 20:50 上传

点击文件名下载附件
如何用VBA进行双条件汇总？

最佳答案

月排行榜 / 总排行榜

枯禅

2010-4-23 21:22

Sub test()
Dim d As Object
Dim arr, arrt
Dim i%, k%
Set d = CreateObject("Scripting.Dictionary")
arr = Range("a2:c" & [a65536].End(3).Row)
For i = 1 To UBound(arr)
    d(arr(i, 1) & "-" & arr(i, 2)) = d(arr(i, 1) & "-" & arr(i, 2)) + arr(i, 3)
Next
arrt = Range("h2:j" & [h65536].End(3).Row)
For k = 1 To UBound(arrt)
    arrt(k, 3) = d(arrt(k, 1) & "-" & arrt(k, 2))
Next
Range("h2:j65536").ClearContents
[h2].Resize(UBound(arrt), 3) = arrt
Set d = Nothing
End Sub

跳转到最佳答案楼层

枯禅

Sub test()
Dim d As Object
Dim arr, arrt(), arr0
Dim i%, k%
Set d = CreateObject("Scripting.Dictionary")
arr = Range("a2:c" & [a65536].End(3).Row)
For i = 1 To UBound(arr)
    d(arr(i, 1) & "-" & arr(i, 2)) = d(arr(i, 1) & "-" & arr(i, 2)) + arr(i, 3)
Next
arrt = d.Keys
ReDim arr0(0 To d.Count - 1, 1 To 3)
For k = LBound(arrt) To UBound(arrt)
    arr0(k, 1) = Split(arrt(k), "-")(0)
    arr0(k, 2) = Split(arrt(k), "-")(1)
    arr0(k, 3) = d(arrt(k))
Next
Range("h2:j65536").ClearContents
[h2].Resize(d.Count, 3) = arr0
Set d = Nothing
End Sub

一剑惊心

这样会打破我条件区域的条件顺序，能不能不要打破此顺序？

枯禅

Sub test()
Dim d As Object
Dim arr, arrt
Dim i%, k%
Set d = CreateObject("Scripting.Dictionary")
arr = Range("a2:c" & [a65536].End(3).Row)
For i = 1 To UBound(arr)
    d(arr(i, 1) & "-" & arr(i, 2)) = d(arr(i, 1) & "-" & arr(i, 2)) + arr(i, 3)
Next
arrt = Range("h2:j" & [h65536].End(3).Row)
For k = 1 To UBound(arrt)
    arrt(k, 3) = d(arrt(k, 1) & "-" & arrt(k, 2))
Next
Range("h2:j65536").ClearContents
[h2].Resize(UBound(arrt), 3) = arrt
Set d = Nothing
End Sub

筱灵之心

枯禅 发表于 2010-4-23 21:22
Sub test()Dim d As ObjectDim arr, arrtDim i%, k%Set d = CreateObject("Scripting.Dictionary")arr = Ra ...

那如果是跨工作簿汇总呢？需要怎么修改?