VBA数据类型自动转换理解

吕?布

爱疯老是有一些问题，有时我也回答不上来，但我隐约感觉是什么原因。

这次，他又发了一个贴。是关于数据类型匹配的。http://excelpx.com/dispbbs.asp?boardid=5&replyid=1299983&id=101555&page=1&skin=0&Star=2

我按我自己的想法理解了一下。发在这里。以后好查找。

yay8c6kO.rar (12.71 KB, 下载次数: 43)

2012-7-5 09:09 上传

点击文件名下载附件

 

 

 

 

 

 

Module mdl数据类型自动转换说明代码如下：

Option Explicit

'1. 类型自动转换机制:
'   VBA看似很聪明,当我们混合使用数据类型时,VBA会使用特别的类型转换机制,把实际输入的数据转换成希望接收的数据类型.
'   比如一个地方要求是一个Dobule类型的,但是提供的是一个String类型,这时VBA会按自己的规则先把String数据转换成一个
'   Double数据再使用.反之亦然.
Sub TypeSelfAdaptation()
    Dim s As String
    Dim i As Integer
    Dim dbl As Double
    dbl = Application.Pi()  'dbl=3.14159265358979
    i = dbl                 'i=3,因为是整型,小数部分被舍去
    s = dbl                 's="3.14159265358979"
    Stop
End Sub

'2. 会进行类型自动转换的情况:
'   2.1 赋值符号=右边的值,不包括Set aObj=SomeObject的情况,因为这是专门针对对象的
'   2.2 运算符两边的值
'   2.3 接受参数的方法或过程里的形式参数
Sub AdaptionCondition()
    Const s = "3.14"
    Dim i As Integer, j As Integer
    Dim dbl As Double

    i = s   '2.1的情况,赋值符号右边的值s从String类型转换成整型.

    dbl = s * s    '2.2的情况,运算符*号右边的值s从String类型转换成Double类型.
    j = 5 Mod s    '2.2的情况,运算符Mod右边的值s从String类型转换成Integer类型.

    MsgBox "VbYesNoCancel,显示 Yes、No 及 Cancel 按钮", s   '2.3的情况,MsgBox函数的Buttons参数输入值s自动由String类型转换成Integer类型.

    Stop
End Sub

'3. 类型自动转换缺点:
'   3.1 由于多做了一件事,会相应多出一些内存开销.
'   3.2 可能引入微妙的难以调试的误

Sub AdaptionDefect()
    '3.1 对于大的数组,明确的定义其元素类型与定义为Variant类型速度差别很大
   
    '3.2 先想想,显示结果是多少,6.14?还是33.14?
    Debug.Print "3" + "3.14"
    Debug.Print CDbl("3") + CDbl("3.14")
End Sub

模块1代码如下：

Option Explicit

'结论:
'把一个区域直接赋给一个Varaint数组,或者把一个数组直接写入一个区域,应是VBA特意写的一种快速交换数据的方法.
'如果要把一个区域直接赋给一个数组,数组变量必须定义为Varaint类型或元素类型为Variant的动态数组

'用[A2:B5]这种形式是区域的快速表示方法
'这种形式进行自动类型转换时,如果是转换成元素类型为Variant的动态数组时,不会默认取其Value属性进行转换,
'如果是直接转换成Variant变量时,会取其Value属性,转换成为包含数组的Variant变量

'如果用Range("A2:B5")这种形式表示区域,进行自动类型转换时,
'会取区域对象的Value属性转换成元素为Variant类型的动态数组或包含数组的Variant变量

Sub a() '错误:Variant()与Variant(1 to 4, 1 to 2),不匹配
'arr(),元素为Variant类型的数组
'[A2:B5],区域快速表达方式,自动类型转换时成动态数组时不取其Value进行转换,这也许是其叫快速的原因吧.arr = Range("A2:B5")可行
    Dim arr()
    arr = [A2:B5]
    'arr = Range("A2:B5")
    Stop
End Sub

Sub b() '错误:String()与Variant(1 to 4, 1 to 2),不匹配
'arr(),String()类型
'[A2:B5].Value,Variant/Variant(1 to 4, 1 to 2)类型,不匹配
    Dim arr() As String
    arr = [A2:B5].Value
    Stop
End Sub

Sub c() '正确:Variant与Variant(1 to 4, 1 to 2),匹配
'[A2:B5]自动转换为Variant类型时,取其Value属性转换成包含数组的Variant变量
    Dim arr
    arr = [A2:B5]
    Stop
End Sub

Sub d() '正确:Variant()与Variant/Variant(1 to 4, 1 to 2),匹配
'已经明确取[A2:B5]的Value属性
    Dim arr() As Variant
    arr = [A2:B5].Value
    Stop
End Sub

Sub e() '错误:Variant()与Variant(1 to 4, 1 to 2),不匹配
'与a一样
    Dim arr() As Variant
    arr = [A2:B5]
    Stop
End Sub

Sub f() '?:Object与Variant(1 to 4, 1 to 2),匹配?
'[A2:B5]本来便是Range类型,用的Set语句,明确等号两边是Object类型.
    Dim Rng As Object
    Set Rng = [A2:B5]
    Stop
End Sub

小福贵

好文章，学习了[em17]

雨狐

学习[em01]

和气生财

还有附件？哈哈，谢谢啦

和气生财

怕你看不到，这儿也贴上来。

“就是这个疑问：variant() 默认是 一维 的么，所以才会与 [a2:b5].value （variant(1to4, 1to2) ）矛盾？“

哇哈哈

学习了。[em02][em02][em02]

东方智彩

学习学习!

echolan

学习,谢楼主分享!

吕?布

QUOTE:

以下是引用和气生财在2009-11-24 12:11:00的发言：

怕你看不到，这儿也贴上来。

“就是这个疑问：variant() 默认是 一维 的么，所以才会与 [a2:b5].value （variant(1to4, 1to2) ）矛盾？“

variant() 是动态数组，不一定是一维。好象没有你讲的那种冲突情况，下面程序可以运行啊

Sub tt()
Dim arr() As Variant
arr = [a2:b5].Value
Stop

End Sub

和气生财

QUOTE:

以下是引用吕?布在2009-11-24 12:38:00的发言：

variant() 是动态数组，不一定是一维。好象没有你讲的那种冲突情况，下面程序可以运行啊

Sub tt()
Dim arr() As Variant
arr = [a2:b5].Value
Stop

End Sub

谢谢解答。

应该是这段。

Sub a()
    Dim arr()
    arr = [A2:B5]
    Stop
End Sub