Excel精英培训网

 找回密码
 注册
数据透视表40+个常用小技巧,让你一次学会!
查看: 965|回复: 4

自动加总公式

[复制链接]
发表于 2023-1-30 01:06 | 显示全部楼层 |阅读模式
请问如何定加公式可以根据每月的1和最后一天的加公式?
月都要的格, 可以用公式自动辩识1到最后一天有多少个单元格总吗?
要注意不是每一天都有时间需要加, 而且中可能 - 的列, 不一定下一行就是下一天, 请参考附件红色的部份, 谢谢!

Sum time with month.rar

9.4 KB, 下载次数: 9

发表于 2023-1-30 11:07 | 显示全部楼层
辅助列,E1
=TEXT(LOOKUP(9^9,A$1:A1/(A$1:A1<>"-")),"yyyymm")<>TEXT(LOOKUP(9^9,A$1:A2/(A$1:A2<>"-")),"yyyymm")


C40
=E40*SUM(OFFSET(C$1,MIN(IF(TEXT(A$1:A39,"yyyymm")=TEXT(LOOKUP(9^9,A$1:A39/(A$1:A39<>"-")),"yyyymm"),ROW(A$1:A39)))-1,,ROW()-MIN(IF(TEXT(A$1:A39,"yyyymm")=TEXT(LOOKUP(9^9,A$1:A39/(A$1:A39<>"-")),"yyyymm"),ROW(A$1:A39)))))
数组公式 , 按Ctrl+Shift+Enter 三键完成

e列 筛选 True
复制C40 ,
选择C40:C110,
Alt + ; (定位可见单元格)
粘贴公式

================================
用技巧 将 "-"全部填上日期, 公式会简单许多


回复

使用道具 举报

发表于 2023-1-30 14:55 | 显示全部楼层
添加标题行,再透视
或者公式如图
=LET(a,UNIQUE(HSTACK(TEXT(A1:A110,"e年m月"),MAP(A1:A110,LAMBDA(x,IF(x<9^9,TEXT(SUM(FILTER(C1:C110,TEXT(A1:A110,"em")=TEXT(x,"em"))),"[h]:mm"),""))))),FILTER(a,TAKE(a,,1)<>"-"))
QQ图片20230130145344.png
回复

使用道具 举报

发表于 2023-1-30 17:50 | 显示全部楼层
C10{=SUM(OFFSET(C$1,MIN(IF(TEXT(A$1:A9,"EM")=TEXT(LOOKUP(9^9,A$1:A9),"EM"),ROW($1:9)))-1,,SUM(PERCENTILE(IF(TEXT(A$1:A9,"EM")=TEXT(LOOKUP(9^9,A$1:A9),"EM"),ROW($1:9)),{1,0})*{1,-1})+1))
11044.png
回复

使用道具 举报

发表于 2023-1-31 14:34 | 显示全部楼层
1. 選取 C2:C110
2. Ctrl+G -> 特殊 -> 空格
3. 在 C2 輸入公式
=IF((MAX(A$1:A1)=EOMONTH(MAX(A$1:A1),0))*(B2=0),SUM(OFFSET(C$1,MATCH(--TEXT(MAX(A$1:A1),"e-m"),A:A,)-1,):C1),"")
4. 按 Ctrl + Enter



log.png
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|Archiver|Excel精英培训 ( 豫ICP备11015029号 )

GMT+8, 2024-3-28 19:37 , Processed in 0.293750 second(s), 10 queries , Gzip On, Yac On.

Powered by Discuz! X3.4

Copyright © 2001-2020, Tencent Cloud.

快速回复 返回顶部 返回列表