满足条件返回一个值，怎样写公式？

飞起一脚

如题，怎样在满足一个条件的前提下，再满足另外3个条件返回一个值。求高手指点！！！

hfwufanhf2006

如果是用函数的话，第一个公式如下：
=IF(S14=1,500,IF(S14=2,450,IF(S14=3,400,IF(S14=4,350,IF(S14=5,300,IF(AND(OR(S14=6,S14=7),O4>Q14,P4>P14,O4>O14),100,0))))))

第二个公式你照这个这个意思类推就行了

我解释下含义：if(条件，满足条件的结果，不满足条件的结果）

可以嵌套,可以只嵌套其中的一个部分，完整形态是：
if(条件1,if(条件2,满足条件1和条件2的结果，满足条件1不满足条件2的结果)，if(条件3，满足条件1和条件3的结果,不满足条件1也不满足条件3的结果))
注意：最后有两个")”，第一个与最后的if对应，第二个与最开始的if对应，中间那个if本身就有两个成对的小括号，结尾就不需要再添加了；
简写一下能看的更明白：if(  , if(  ,  ,   ),if(   ,   ,   )),总之括号成对就行了，而且不能把次序弄反了；
嵌套的公式中还能再嵌套，最新版的最多能嵌套64层，嵌套不难写，重点是要把小括号的位置写对；

or(条件1,条件2,...)：条件1成立或者条件2成立或者...可以写很多；
and(条件1,条件2,...)：条件1成立并且条件2成立并且...也可以写很多；


你再回头看一下上面的公式，应该就能明白；

飞起一脚

hfwufanhf2006 发表于 2020-1-9 10:17
如果是用函数的话，第一个公式如下：
=IF(S14=1,500,IF(S14=2,450,IF(S14=3,400,IF(S14=4,350,IF(S14=5,30 ...

非常感谢

砂海

公式1
假设s14的值为整数1到6 , 这样就好
=CHOOSE(S14,500,450,400,350,300,SUMPRODUCT(($O4:$Q4>=$O$14:$Q$14)*100))
-----------------------------------------------------------------------------------------------------------------
而实际情况中  , S14的值 为 正整数(即 s14可能= 8,9,10,...)

=CHOOSE(LOOKUP(S14,{1,2,3,4,5,6,8},{1,2,3,4,5,6,7}),500,450,400,350,300,SUMPRODUCT(($O4:$Q4>=$O$14:$Q$14)*100),0)
   .....
橙色部分 , 将s14的值转换
1-6 不变
7变为6
8以上 变为7

=choose( 数字 , 第一种情况 , 第二种情况 , 第三种情况 [,...])=======================================================================
=======================================================================

你的要求 "当为6或者7的时候，且O4、P4、Q4均大于或等于O14、P14、Q14的时候返回一个值100."

我上面公式有错 , 更改 为
=CHOOSE(LOOKUP(S14,{1,2,3,4,5,6,8},{1,2,3,4,5,6,7}),500,450,400,350,300,(SUMPRODUCT(($O4:$Q4>=$O$14:$Q$14)*1)=3)*100,0)

飞起一脚

砂海 发表于 2020-1-9 11:31
公式1
假设s14的值为整数1到6 , 这样就好
=CHOOSE(S14,500,450,400,350,300,SUMPRODUCT(($O4:$Q4>=$O$14: ...

又怎样设置如果S列没有教师则不显显示或为0

cutecpu

飞起一脚 发表于 2020-1-10 11:29
又怎样设置如果S列没有教师则不显显示或为0

您好，加上 IF 判斷:
IF(S某單元格="","",原公式)

飞起一脚

砂海 发表于 2020-1-9 11:31
公式1
假设s14的值为整数1到6 , 这样就好
=CHOOSE(S14,500,450,400,350,300,SUMPRODUCT(($O4:$Q4>=$O$14: ...

学习了，谢谢！怎样设置如果s5（某个单元格没有姓名，就是空白）的时候，不显或者为0

飞起一脚

cutecpu 发表于 2020-1-10 15:49
您好，加上 IF 判斷:
IF(S某單元格="","",原公式)

我试着修改了一下，不会。

cutecpu

飞起一脚 发表于 2020-1-10 19:26
我试着修改了一下，不会。

您好，可以上傳附件
註記是哪一個儲存格的公式不會修改

飞起一脚

cutecpu 发表于 2020-1-10 19:31
您好，可以上傳附件
註記是哪一個儲存格的公式不會修改

用你这个方法去修改短一点的公式可以。