二列数据对比，然后提取A列没有的数据倒C列

wulangzi650

我现在有二个工作表，工作表A和B的A列都有数据我要把工作表B A列的数据和工作表A A列的数据对比。然后工作表B A列没有的数据都提取倒工作表B A列的下面。工作表A里A列的数据每个月都要增加。修改

mytto88

Sub kk()
    Dim dic As Object, arr_A(), arr_B(), arr()
    Set dic = CreateObject("scripting.dictionary")
    irow = Sheet1.Cells(Rows.Count, 1).End(3).Row
    arr_A = Sheet1.Range("a2:a" & irow).Value
    ReDim arr(1 To UBound(arr_A), 1 To 1)
    irow = Sheet2.Cells(Rows.Count, 1).End(3).Row
    arr_B = Sheet2.Range("a2:a" & irow).Value
    For i = 1 To UBound(arr_B)
        dic(arr_B(i, 1)) = ""
    Next i
   
    For i = 1 To UBound(arr_A)
        If dic.exists(arr_A(i, 1)) = False Then
            n = n + 1
            arr(n, 1) = arr_A(i, 1)
        End If
    Next i
   
    With Sheet2
        .Range("a" & irow + 1).Resize(n, 1) = arr
    End With
End Sub

wulangzi650

mytto88 发表于 2019-8-17 20:32
Sub kk()
    Dim dic As Object, arr_A(), arr_B(), arr()
    Set dic = CreateObject("scripting.dict ...

老师你好。能不能加一个判断，现在如果说没有新增的时候就会报错。、加个判断就是如果本月无新境货号

mytto88

With Sheet2
        If n > 0 Then
            .Range("a" & irow + 1).Resize(n, 1) = arr
        End If
End With