[已解决]请教一下这种COUNTIF该怎样表现？？

Ishtonz

各位大神，

1、B21如何表现（求最优组合下的分布情况，是否应该使用countif）*最优组合是指：
M列的价格最低的，找到相应的渠道（N列），根据N列的值（比如SPP(CTT）找到所对应的(WHCTT）下的数字
如3行，就应该记为8-4这样。


2、N13 在J13与L13同等值的情况下，优先index L1,如何才能做到？优先级别为1-2-3。

先谢谢。

最佳答案

月排行榜 / 总排行榜

AmoKat

2017-7-30 20:22

Ishtonz 发表于 2017-7-30 16:53
N3 =VLOOKUP(S3,IF({1,0},N(OFFSET(G3,,{0;1;4;5;2;3})),T(OFFSET(G$1,,{0;1;4;5;2;3}))),2,)

你好， ...

M3 =MIN(IF(G3:L3>0,G3:L3))
下拉複製公式，組數公式CTRL+SHIFT+ENTER輸入公式

N3 =VLOOKUP(S3,IF({1,0},N(OFFSET(G3,,{0;1;4;5;2;3})),T(OFFSET(G$1,,{0;1;4;5;2;3}))),2,)
下拉複製公式

B18 =COUNTIF(OFFSET($A$3:$A$14,,MATCH($A18,$1:$1,)-1),B$17)
右拉複製公式

B21 =SUM(N(IF((MID($N3:$N14,1,3)=$A2:$F2)*(MID($N3:$N14,5,3)=RIGHT(T(OFFSET($A$1,,{0,0,2,2,4,4})),3)),$A3:$F14,)=B17))
右拉複製公式，組數公式CTRL+SHIFT+ENTER輸入公式

跳转到最佳答案楼层

Ishtonz

以上是困扰很久的两个问题，尤其第一个感觉非常困难。

cabcyvr

1、B21如何表现（最优组合下的分布情况）
因为你没有说明何种情况为“最优”，以下是我自己理解的“最优”情况
对于同一列的18：20，哪个数字大就取对应的A18：A20代码，同样大的数字取行数大的A列代码
如果全为0，显示空

B21=IF(SUM(B18:B20)=0,"",INDEX($A$18:$A$20,MAX(IF(B18:B20=MAX(B18:B20),ROW(B18:B20)-17))))     数组三键执行后右拉复制

2、N13 在J13与L13同等值的情况下，优先index L1,如何才能做到

N3=INDEX($G$1:$L$1,MAX(IF(G3:L3=M3,COLUMN(G3:L3)-6)))    数组三键执行后下拉复制

注：上面的公式没有按照你说的优先级写，如果理解正确，并且 N4=SPP(LLA)    N13=GRO(HOU)，
N3的公式要改为
N3=INDEX($G$1:$L$1,IF(COUNTIF(G3:H3,M3)>0,MAX(IF(G3:H3=M3,COLUMN(G3:H3)-6)),MAX(IF(I3:L3=M3,COLUMN(I3:L3)-6)))) 数组三键执行后下拉复制



3. 顺便提一下，仅供参考 B18：H20内的结果也可以用一个公式得到。

B18=COUNTIF(OFFSET($A$2,1,MATCH($A18,$A$1:$F$1,)-1,12,1),B$17)     数组三键执行后向右向下复制到H20

AmoKat

M3 =MIN(IF(G3:L3>0,G3:L3))
下拉複製公式，組數公式CTRL+SHIFT+ENTER輸入公式

N3 =VLOOKUP(S3,IF({1,0},N(OFFSET(G3,,{0;1;4;5;2;3})),T(OFFSET(G$1,,{0;1;4;5;2;3}))),2,)
下拉複製公式

B18 =COUNTIF(OFFSET($A$3:$A$14,,MATCH($A18,$1:$1,)-1),B$17)
右拉複製公式

B21 =IF(SUM(B18:B20),LOOKUP(,0/(MAX(B18:B20)=B18:B20),$A18:$A20),"")
右拉複製公式

Ishtonz

首先谢谢楼上两位大神的建议，先mark后周末看看效果如何！

Ishtonz

cabcyvr 发表于 2017-7-29 05:16
1、B21如何表现（最优组合下的分布情况）
因为你没有说明何种情况为“最优”，以下是我自己理解的“最优” ...

大神，不好意思我没有说清楚最优组合的意义，请查看图片。最优组合的意思应该衍生为“使用最优渠道情况下，A3：F14的分布情况。

这个问题实在困扰很久，一直没有好的办法解决！

Ishtonz

AmoKat 发表于 2017-7-29 10:03
M3 =MIN(IF(G3:L3>0,G3:L3))
下拉複製公式，組數公式CTRL+SHIFT+ENTER輸入公式

N3 =VLOOKUP(S3,IF({1,0},N(OFFSET(G3,,{0;1;4;5;2;3})),T(OFFSET(G$1,,{0;1;4;5;2;3}))),2,)

你好，完美解决了问题2！
现在就是剩下问题1~，求助

Ishtonz

cabcyvr 发表于 2017-7-29 05:16
1、B21如何表现（最优组合下的分布情况）
因为你没有说明何种情况为“最优”，以下是我自己理解的“最优” ...

N3=INDEX($G$1:$L$1,IF(COUNTIF(G3:H3,M3)>0,MAX(IF(G3:H3=M3,COLUMN(G3:H3)-6)),MAX(IF(I3:L3=M3,COLUMN(I3:L3)-6))))

这个方法也完美解决了疑惑。
想了解一下，COLUMN(G3:H3)-6 为什么要-6？

AmoKat

Ishtonz 发表于 2017-7-30 16:53
N3 =VLOOKUP(S3,IF({1,0},N(OFFSET(G3,,{0;1;4;5;2;3})),T(OFFSET(G$1,,{0;1;4;5;2;3}))),2,)

你好， ...

M3 =MIN(IF(G3:L3>0,G3:L3))
下拉複製公式，組數公式CTRL+SHIFT+ENTER輸入公式

N3 =VLOOKUP(S3,IF({1,0},N(OFFSET(G3,,{0;1;4;5;2;3})),T(OFFSET(G$1,,{0;1;4;5;2;3}))),2,)
下拉複製公式

B18 =COUNTIF(OFFSET($A$3:$A$14,,MATCH($A18,$1:$1,)-1),B$17)
右拉複製公式

B21 =SUM(N(IF((MID($N3:$N14,1,3)=$A2:$F2)*(MID($N3:$N14,5,3)=RIGHT(T(OFFSET($A$1,,{0,0,2,2,4,4})),3)),$A3:$F14,)=B17))
右拉複製公式，組數公式CTRL+SHIFT+ENTER輸入公式

AmoKat

B21 =SUM(N(IF((MID($N3:$N14,1,3)=$A2:$F2)*(MID($N3:$N14,5,3)=RIGHT(T(OFFSET($A$1,,{0,0,2,2,4,4})),3)),$A3:$F14,)=B17))