[已解决]遍历区域内所有单元格

不二周助

为什么当rng = Range("A1:C12")时，使用For Each cel In rng.Columns(1)后cel的地址是$A$1:$A$12，不能遍历第一列所有单元格，而当rng = Range("A1:A12")时，使用For Each cel In rng却可以遍历所有单元格

最佳答案

月排行榜 / 总排行榜

爱疯

2017-2-17 09:48

不二周助 发表于 2017-2-16 21:13
看了您的回复自己想了一下想明白了，遍历第一列的所有单元格可以用For Each cel In rng.Columns(1).Cells， ...

Sub test1()
    Dim rng As Range
    Set rng = Range("A1:C5")
    Call test2(rng.Rows)
    Call test2(rng.Columns)
    Call test2(rng.Columns(1))
    Call test2(rng.Columns(1).Cells)
End Sub

Sub test2(temp As Range)
    Dim cel As Range
    Debug.Print "-------------------"
    For Each cel In temp
        Debug.Print cel.Address(0, 0)
    Next
End Sub


最右是什么对象的集合，循环变量就是什么对象。

跳转到最佳答案楼层

爱疯

Sub test()
    Dim rng As Range, cel As Range
    Set rng = Range("A1:C12")

    '情况1
    Debug.Print "集合是rng里的所有列，遍历每1列"
    For Each cel In rng.Columns
        Debug.Print cel.Address(0, 0)
    Next

    '情况2
    Debug.Print "集合是rng里的所有行，遍历每1行"
    For Each cel In rng.Rows
        Debug.Print cel.Address(0, 0)
    Next

    '情况3
    Debug.Print "集合是rng里的第1列，遍历每1列"
    For Each cel In rng.Rows.Columns(1)
        Debug.Print cel.Address(0, 0)
    Next
End Sub

爱疯

集合是rng里的所有列，遍历每1列
A1:A12
B1:B12
C1:C12
集合是rng里的所有行，遍历每1行
A1:C1
A2:C2
A3:C3
A4:C4
A5:C5
A6:C6
A7:C7
A8:C8
A9:C9
A10:C10
A11:C11
A12:C12
集合是rng里的第1列，遍历每1列
A1:A12






for each 循环变量 in 集合
  循环体
next  循环变量
对于情况3，集合也是列的集合，并且该集合中只有1列（即第1列）。
在情况3的集合中进行循环，只会执行1次循环。

不二周助

看了您的回复自己想了一下想明白了，遍历第一列的所有单元格可以用For Each cel In rng.Columns(1).Cells，谢谢~

爱疯

不二周助 发表于 2017-2-16 21:13
看了您的回复自己想了一下想明白了，遍历第一列的所有单元格可以用For Each cel In rng.Columns(1).Cells， ...

Sub test1()
    Dim rng As Range
    Set rng = Range("A1:C5")
    Call test2(rng.Rows)
    Call test2(rng.Columns)
    Call test2(rng.Columns(1))
    Call test2(rng.Columns(1).Cells)
End Sub

Sub test2(temp As Range)
    Dim cel As Range
    Debug.Print "-------------------"
    For Each cel In temp
        Debug.Print cel.Address(0, 0)
    Next
End Sub


最右是什么对象的集合，循环变量就是什么对象。