[已解决]为什么提示“类型不匹配”

lingyuncelia1

运行以下代码，为什么提示“类型不匹配”，但是如果A3也有东西存在，就正常运行？
Sub 提取手机号码()
    arr = Range("a2:a" & Range("a65536").End(3).Row)
    Set reg = CreateObject("vbscript.regexp")
    reg.Pattern = "1[3578]\d{9}(?=\D|1[3578]\d{9}|$)"
    reg.Global = True
    For i = 1 To UBound(arr, 1)
        s = arr(i, 1)
        If reg.test(s) Then
            Set mymatch = reg.Execute(s)
            m = 2
            For Each mat In mymatch
                Cells(i + 1, m) = mat
                m = m + 1
            Next
        End If
    Next i
End Sub

最佳答案

月排行榜 / 总排行榜

zjdh

2017-1-5 21:22

一个单元赋值给arr，不成数组！可作如下改动
Sub 提取手机号码()
    arr = Range("A2:A" & Range("A65536").End(3).Row)
    Set reg = CreateObject("vbscript.regexp")
    reg.Pattern = "1[3578]\d{9}(?=\D|1[3578]\d{9}|$)"
    reg.Global = True
    If IsArray(arr) Then     '是数组
        For i = 1 To UBound(arr, 1)
            s = arr(i, 1)
            If reg.test(s) Then
                Set mymatch = reg.Execute(s)
                m = 2
                For Each mat In mymatch
                    Cells(i + 1, m) = mat
                    m = m + 1
                Next
            End If
        Next i
    Else        '非数组
        Set mymatch = reg.Execute(arr)
        m = 2
        For Each mat In mymatch
            Cells(2, m) = mat
            m = m + 1
        Next
    End If
End Sub

跳转到最佳答案楼层

爱疯

这里，第一句arr实际返回的是一个值，并非一个数组。
比如再多弄一个数据放在a3里，应该就不会报这个错误了。

需要先看数据源是怎样（变化）的，再才好确定如何赋给数组arr。

zjdh

一个单元赋值给arr，不成数组！可作如下改动
Sub 提取手机号码()
    arr = Range("A2:A" & Range("A65536").End(3).Row)
    Set reg = CreateObject("vbscript.regexp")
    reg.Pattern = "1[3578]\d{9}(?=\D|1[3578]\d{9}|$)"
    reg.Global = True
    If IsArray(arr) Then     '是数组
        For i = 1 To UBound(arr, 1)
            s = arr(i, 1)
            If reg.test(s) Then
                Set mymatch = reg.Execute(s)
                m = 2
                For Each mat In mymatch
                    Cells(i + 1, m) = mat
                    m = m + 1
                Next
            End If
        Next i
    Else        '非数组
        Set mymatch = reg.Execute(arr)
        m = 2
        For Each mat In mymatch
            Cells(2, m) = mat
            m = m + 1
        Next
    End If
End Sub

zjdh

或这样改
Sub 提取手机号码2()   '或
    arr = Range("A1:A" & Range("A65536").End(3).Row)
    Set reg = CreateObject("vbscript.regexp")
    reg.Pattern = "1[3578]\d{9}(?=\D|1[3578]\d{9}|$)"
    reg.Global = True
       For i = 2 To UBound(arr, 1)
            s = arr(i, 1)
            If reg.test(s) Then
                Set mymatch = reg.Execute(s)
                m = 2
                For Each mat In mymatch
                    Cells(i, m) = mat
                    m = m + 1
                Next
            End If
        Next i
End Sub