[已解决]排序

fgt258

sort能对表格直接排序，如何能让它能把表格放入数组后，直接对数组排序

最佳答案

月排行榜 / 总排行榜

爱疯

2016-11-24 09:51

二维数组排序.rar (8.98 KB, 下载次数: 7)

2016-11-24 09:48 上传

点击文件名下载附件

好处：容易理解，方便修改。
坏处：效率低。




Dim A
Sub test()
    Dim B, i, x
    x = InputBox("列号:", "输入", 4)
    A = Range("a1").CurrentRegion
    ReDim B(2 To UBound(A))
    '按第 x 列进行排序
    For i = 2 To UBound(A)
        B(i) = A(i, x)
    Next i
    Call BubbleSort(B)
    [a21].Resize(UBound(A), UBound(A, 2)) = A
End Sub

'冒泡排序
Sub BubbleSort(Arr)
    Dim l&, u&, i&, j&
    l = LBound(Arr): u = UBound(Arr)
    For i = l To u - 1
        For j = u To i + 1 Step -1
            If Arr(j) < Arr(j - 1) Then Swap Arr(j), Arr(j - 1): Swap2 j, j - 1  '升序
        Next j
    Next i
End Sub

'互换辅助数组中的两个值
Sub Swap(x, y)
    Dim temp
    temp = x: x = y: y = temp
End Sub

'互换实际数据中的两行
Sub Swap2(x, y)
    Dim temp, j
    For j = 1 To UBound(A, 2)
        temp = A(x, j): A(x, j) = A(y, j): A(y, j) = temp
    Next j
End Sub

跳转到最佳答案楼层

望帝春心

这个是不是有点像让男人生孩子啊

望帝春心

排序方法很多，可以去了解一下

望帝春心

也可以用SORT在工作表中排好序再写入数组

fgt258

http://club.excelhome.net/thread-1102706-1-1.html六楼的功能可以，但是排序不如意（1,2,6,15,30）排出来是（1,15,2,30,6）大师能改下吗

望帝春心

fgt258 发表于 2016-11-24 08:25
http://club.excelhome.net/thread-1102706-1-1.html六楼的功能可以，但是排序不如意（1,2,6,15,30）排出来 ...

看了下原帖，原来是这么高能的东西，不会这个
看看兰版的VBA80集，里面讲了好几种VBA排序的方法

fgt258

不想在表格上体现，数据大会很卡。所以想有没有直接在内存中排序的

爱疯

二维数组排序.rar (8.98 KB, 下载次数: 7)

2016-11-24 09:48 上传

点击文件名下载附件

好处：容易理解，方便修改。
坏处：效率低。




Dim A
Sub test()
    Dim B, i, x
    x = InputBox("列号:", "输入", 4)
    A = Range("a1").CurrentRegion
    ReDim B(2 To UBound(A))
    '按第 x 列进行排序
    For i = 2 To UBound(A)
        B(i) = A(i, x)
    Next i
    Call BubbleSort(B)
    [a21].Resize(UBound(A), UBound(A, 2)) = A
End Sub

'冒泡排序
Sub BubbleSort(Arr)
    Dim l&, u&, i&, j&
    l = LBound(Arr): u = UBound(Arr)
    For i = l To u - 1
        For j = u To i + 1 Step -1
            If Arr(j) < Arr(j - 1) Then Swap Arr(j), Arr(j - 1): Swap2 j, j - 1  '升序
        Next j
    Next i
End Sub

'互换辅助数组中的两个值
Sub Swap(x, y)
    Dim temp
    temp = x: x = y: y = temp
End Sub

'互换实际数据中的两行
Sub Swap2(x, y)
    Dim temp, j
    For j = 1 To UBound(A, 2)
        temp = A(x, j): A(x, j) = A(y, j): A(y, j) = temp
    Next j
End Sub

望帝春心

fgt258 发表于 2016-11-24 09:47
不想在表格上体现，数据大会很卡。所以想有没有直接在内存中排序的

我理解错了那个SORT，学习下版主回复的方法吧。

fgt258

天啊，这么复杂，比脑筋急转弯的弯度还大，还以为内存排序只是一个函数的事呢