[已解决]求VBA中计算字符串长度的函数

stephy1128

各位大侠，想请教一下关于VBA中计算字符串的长度，计算规则是：中文字符算两个字节、英文字符算一个字节，中文字后面是英文的那么这个中文字算三个字节、中文字做开头的那么这个中文字算三个字节、中文字做结尾的那么这个中文字算三个字节。

例如：我是ABC              按以上计算规则应该是"_我是_ABC",共9个字节。
         我是ABC是我        按以上计算规则应该是"_我是_ABC_是我_",共15个字节

求计算这种字符串长度的函数，谢谢！

最佳答案

月排行榜 / 总排行榜

爱疯

2016-7-13 16:28

Sub test()
    MsgBox bytesCount("我是ABC")
End Sub

Function bytesCount(Str As String) As Long
    Dim cn As String
    Dim en As String
    Dim s As Integer

    cn = "[\u4E00-\u9FA5]"
    en = "[a-zA-Z]"

    With CreateObject("VBScript.RegExp")
        .Global = True

        '中文字符算两个字节
        .Pattern = cn
        s = s + .Execute(Str).Count * 2

        '英文字符算一个字节
        .Pattern = en
        s = s + .Execute(Str).Count * 1

        '中文后是英文，就加1个字节
        .Pattern = cn & en
        s = s + .Execute(Str).Count

        '英文后是中文，就加1个字节
        .Pattern = en & cn
        s = s + .Execute(Str).Count

        '中文开头，并且第2个也是中文，就加1个字节
        .Pattern = "^" & cn & cn
        If .test(Str) Then s = s + 1

        '中文结尾，并且倒数第2个也是中文，就加1个字节
        .Pattern = cn & cn & "$"
        If .test(Str) Then s = s + 1
    End With

    bytesCount = s
End Function



较8楼，简化了一点。

跳转到最佳答案楼层

望帝春心

1. Sub Greenhand()
   
2.     Dim i%, str As String
   
3.     str = StrConv("我是ABC", vbFromUnicode)
   
4.     i = LenB(str)
   
5.     MsgBox i
   
6. End Sub
   

复制代码

Strconv供参考

stephy1128

望帝春心 发表于 2016-7-13 14:28
Strconv供参考

你好，按你的函数计算出来的结果是7，但按我上边的那个计算逻辑, 我是ABC计算出来的长度应该是9才对啊。因为“我”的前边和“A”的后边应该格加一个字节才行。

望帝春心

stephy1128 发表于 2016-7-13 14:40
你好，按你的函数计算出来的结果是7，但按我上边的那个计算逻辑, 我是ABC计算出来的长度应该是9才对啊。因 ...

你的两个下划线我没敲，让你参考没让你抄啊。。。

望帝春心

stephy1128 发表于 2016-7-13 14:40
你好，按你的函数计算出来的结果是7，但按我上边的那个计算逻辑, 我是ABC计算出来的长度应该是9才对啊。因 ...

领会精神啊，我是VBA菜鸟

stephy1128

望帝春心 发表于 2016-7-13 15:23
领会精神啊，我是VBA菜鸟

我的意思是，我输入“我是ABC”，返回的字符长度应该是9，那些下划线不是输进去的，我只是用来标识有下划线那个地方应该加多一个字节。

能帮忙再看看吗？谢谢！

望帝春心

stephy1128 发表于 2016-7-13 15:36
我的意思是，我输入“我是ABC”，返回的字符长度应该是9，那些下划线不是输进去的，我只是用来标识有下划 ...

哦，好吧，不懂了

爱疯

Sub test()
    MsgBox bytesCount("我是ABC")
End Sub

Function bytesCount(Str As String) As Long
    Dim cn As String
    Dim en As String
    Dim s As Integer

    cn = "[\u4E00-\u9FA5]"
    en = "[a-zA-Z]"

    With CreateObject("VBScript.RegExp")
        .Global = True

        '中文字符算两个字节
        .Pattern = cn
        s = s + .Execute(Str).Count * 2

        '英文字符算一个字节
        .Pattern = en
        s = s + .Execute(Str).Count * 1

        '中文后是英文，就加1个字节
        .Pattern = cn & en
        s = s + .Execute(Str).Count

        '英文后是中文，就加1个字节
        .Pattern = en & cn
        s = s + .Execute(Str).Count

        '中文开头，并且第2个也是中文，就加1个字节
        .Pattern = "^" & cn
        If .test(Str) Then
            .Pattern = cn
            If .test(Mid(Str, 2, 1)) Then
                s = s + 1
            End If
        End If

        '中文结尾，并且倒数第2个也是中文，就加1个字节
        .Pattern = cn & "$"
        If .test(Str) Then
            .Pattern = cn
            If .test(Mid(Str, Len(Str) - 1, 1)) Then
                s = s + 1
            End If
        End If
    End With

    bytesCount = s
End Function

爱疯

Sub test()
    MsgBox bytesCount("我是ABC")
End Sub

Function bytesCount(Str As String) As Long
    Dim cn As String
    Dim en As String
    Dim s As Integer

    cn = "[\u4E00-\u9FA5]"
    en = "[a-zA-Z]"

    With CreateObject("VBScript.RegExp")
        .Global = True

        '中文字符算两个字节
        .Pattern = cn
        s = s + .Execute(Str).Count * 2

        '英文字符算一个字节
        .Pattern = en
        s = s + .Execute(Str).Count * 1

        '中文后是英文，就加1个字节
        .Pattern = cn & en
        s = s + .Execute(Str).Count

        '英文后是中文，就加1个字节
        .Pattern = en & cn
        s = s + .Execute(Str).Count

        '中文开头，并且第2个也是中文，就加1个字节
        .Pattern = "^" & cn & cn
        If .test(Str) Then s = s + 1

        '中文结尾，并且倒数第2个也是中文，就加1个字节
        .Pattern = cn & cn & "$"
        If .test(Str) Then s = s + 1
    End With

    bytesCount = s
End Function



较8楼，简化了一点。

stephy1128

爱疯 发表于 2016-7-13 16:28
Sub test()
    MsgBox bytesCount("我是ABC")
End Sub

你好，如果还要考虑全角符号和半角符号呢？全角符号与CH规则一样，半角符号与EN规则一样的