[已解决]vba实现统计均分

hjhjxb

vba实现统计均分 vba实现统计均分.rar (14.93 KB, 下载次数: 12)

2016-3-9 20:28 上传

点击文件名下载附件


Sub 求均分()
Dim i As Integer, j As Integer
i = Sheets("8.1").Range("a65536").End(xlUp).Row
For j = 3 To 10
Sheets("成绩分析").Range(Cells(3, j - 1)) = Application.Average(Sheets("8.1").Range(Cells(3, j), Cells(i, j)))
Exit For
Next j
End Sub
程序要修改一下。希望高手用不同方法搞定，顺便也修改我的这段代码。

最佳答案

月排行榜 / 总排行榜

grf1973

2016-3-10 10:54

你原来代码几个错误的地方：
1、Sheets("成绩分析").Range(Cells(3, j - 1)) 是错的。单个单元格区域表示用cells(a,b)就行了。
2、Application.Average(Sheets("8.1").Range(Cells(3, j), Cells(i, j))) 里面的区域表示错了。里面的cells(3,j)和cells(i,j)均应指定工作表，否则会认为是当前工作表的cells(3,j)，除非代码放在Sheets("8.1")里，或者Sheets("8.1")为当前工作表。
3、Exit For那句多余。

跳转到最佳答案楼层

上清宫主

非数值型数据均未计入统计对象：
Sub ave()
Dim ar()
With Sheets("8.1")
   i1% = .[c65536].End(3).Row
   If i1 < 3 Then Exit Sub
   ar = .[c1].Resize(i1, 8).Value
End With
For i1 = 1 To 8
    ar(1, i1) = 0
    ar(2, i1) = 0
    For i2% = 3 To UBound(ar)
        If VarType(ar(i2, i1)) = 5 Then
          ar(1, i1) = ar(1, i1) + 1
          ar(2, i1) = ar(2, i1) + ar(i2, i1)
        End If
    Next
    If ar(1, i1) Then ar(1, i1) = ar(2, i1) / ar(1, i1)
Next
Sheets("成绩分析").[b3:i3] = ar
End Sub

hjhjxb

初学有的地方不是很明白

hjhjxb

上清宫主 发表于 2016-3-9 20:30
非数值型数据均未计入统计对象：
Sub ave()
Dim ar()

自己也写了一段代码帮看一下怎样改才能实现实现？你写的代码下在消化中。

grf1973

Sub 求均分()
    Dim i As Integer, j As Integer
    With Sheets("8.1")
        i = .Range("a65536").End(xlUp).Row
        For j = 3 To 10
            Sheets("成绩分析").Cells(3, j - 1) = Application.WorksheetFunction.Average(.Range(.Cells(3, j), .Cells(i, j)))
        Next j
    End With
End Sub

grf1973

你原来代码几个错误的地方：
1、Sheets("成绩分析").Range(Cells(3, j - 1)) 是错的。单个单元格区域表示用cells(a,b)就行了。
2、Application.Average(Sheets("8.1").Range(Cells(3, j), Cells(i, j))) 里面的区域表示错了。里面的cells(3,j)和cells(i,j)均应指定工作表，否则会认为是当前工作表的cells(3,j)，除非代码放在Sheets("8.1")里，或者Sheets("8.1")为当前工作表。
3、Exit For那句多余。

hjhjxb

grf1973 发表于 2016-3-10 10:54
你原来代码几个错误的地方：
1、Sheets("成绩分析").Range(Cells(3, j - 1)) 是错的。单个单元格区域表示用 ...

学到不少东西，谢谢！初学者就希望有人指点一下。