[已解决]EXCEL高手VBA统计一行三个速度太慢如何优化

lmze2000

1. Sub Tj()
   
2.     n = Cells(Rows.Count, "k").End(3).Row - 10
   
3.     arr = [c11:h192]: brr = [k11:m11].Resize(n)
   
4.     ReDim crr(1 To n, 1 To 1)
   
5.     [p11].Resize(Rows.Count - 20).ClearContents
   
6.     t = Timer
   
7.     For br = 1 To UBound(brr)
   
8.         For ar = 1 To UBound(arr)
   
9.             s = 0
   
10.             For i = 1 To 3
    
11.                 For j = 1 To 6
    
12.                     If brr(br, i) = arr(ar, j) Then s = s + 1
    
13.                 Next j
    
14.             Next i
    
15.             If s = 3 Then js = js + 1
    
16.         Next
    
17.         crr(br, 1) = js
    
18.         js = 0
    
19.     Next
    
20.     [p11].Resize(n) = crr
    
21.     MsgBox "统计完成,用时" & Format(Timer - t, "0.00") & "秒"
    
22. End Sub
    

复制代码

grf1973

搞个快的

1. Sub Tj1()
   
2.     n = Cells(Rows.Count, "k").End(3).Row - 10
   
3.     arr = [c11:h192]: brr = [k11:m11].Resize(n)
   
4.     amax = Application.Max(arr)
   
5.     ReDim xrr%(1 To amax, 1 To amax, 1 To amax)
   
6.     ReDim crr%(1 To n, 1 To 1)
   
7.     [p11].Resize(Rows.Count - 20).ClearContents
   
8.     t = Timer
   
9.    
   
10.     For ar = 1 To UBound(arr)
    
11.         For i = 1 To UBound(arr, 2) - 2
    
12.             For j = i + 1 To UBound(arr, 2) - 1
    
13.                 For k = j + 1 To UBound(arr, 2)
    
14.                     xrr(arr(ar, i), arr(ar, j), arr(ar, k)) = xrr(arr(ar, i), arr(ar, j), arr(ar, k)) + 1
    
15.                 Next
    
16.             Next
    
17.         Next
    
18.     Next
    
19.    
    
20.     For br = 1 To UBound(brr)
    
21.         crr(br, 1) = xrr(brr(br, 1), brr(br, 2), brr(br, 3))
    
22.     Next
    
23.    
    
24.     [p11].Resize(n) = crr
    
25.     MsgBox "统计完成,用时" & Format(Timer - t, "0.00") & "秒"
    
26. End Sub
    

复制代码

lmze2000

grf1973 发表于 2015-4-18 21:21
搞个快的

Grf兄，你这个是什么原理啊，速度又提升好多啊。
这个代码没有看明白是怎么回事。

grf1973

lmze2000 发表于 2015-4-19 09:09
Grf兄，你这个是什么原理啊，速度又提升好多啊。
这个代码没有看明白是怎么回事。

原理很简单，
1、定义三维数组xrr存储结果，三维数组的下标即是所要求的组合条件。比如xrr(1,2,3)存储"1,2,3"的出现次数，xrr(2,3,5)存储“2，3，5”的出现次数。
2、根据给出的数据计算xrr。对于每一行，在里面任取三数从小到大组合，xrr对应位置+1。比如对于第一行“5，9，13，15，17，21”，xrr(5,9,13)=1,xrr(5,9,15)=1,...xrr(15,17,21)=1。如果某行含“1，2，3”，那么 xrr（1，2，3）=xrr(1,2,3)+1
3、根据给定条件取出xrr就是结果。“1，2，3”的出现次数=xrr（1，2，3）。。。。。
4、题目给定的数据和组合条件都是从小到大排好序的，可以极大降低复杂度。如果是乱序的话，就要考虑xrr(1,2,3),xrr(1,3,2),...,xrr(3,2,1)等各种情况。

lmze2000

grf1973 发表于 2015-4-19 15:43
原理很简单，
1、定义三维数组xrr存储结果，三维数组的下标即是所要求的组合条件。比如xrr(1,2,3)存储"1 ...

好法子，谢谢Grf讲解{:021:}
xrr(arr(ar, i), arr(ar, j), arr(ar, k)) = xrr(arr(ar, i), arr(ar, j), arr(ar, k)) + 1 这句有点类似于字典的计数器用法，，明白了。