[已结贴][函中201401]第一讲E组学员作业提交贴

ANDY0393

1、作业统一贴公式.  条件格式的参考备注
2、课程讲到if简写的思路,公式没简化的统一评分5/10.简化(不限思路)的10+/10+
2、跟帖不要重复占楼,要修改直接在原楼层编辑，不要回复学委的批改;本帖已设置回帖仅作者可见；
3、非本组学员请勿跟帖，否则扣分删帖处理；
4、作业截止时间：2014年8月20日晚18:00，过期不予批改
5、8-19(下周二)开始评分,之后修改公式的,评分不改

备注:
步骤      1, 选中   a1:d60
             2.公式a1:b1

  或者   1.公式a1:b1
            2.格式应用于   a1:d60

ANDY0393

  大家这次交作业都很自觉,并且答案都是多种方法,谢谢大家配合组长的工作.大家继续加油.
下边就贴几个比较有代表的公式,仅供参考,思路最重要.
1.

1. =IF(C5>B5,B5,B5*0.95)

复制代码

1.   =MAX(C5>B5,0.95)*B5

复制代码

2.

1. =IF(B18>20,400,IF(B18>10,300,200))

复制代码

1. =-INT(-B18/10-1)/1%

复制代码

3.

1. =IF(MOD(MID(B27,17,1),2),"男","女")

复制代码

1. =TEXT(-1^MID(B27,9,9),"女;男")
   

复制代码

ps:  =IF(B18>20,400,IF(B18>10,300,200)) 类似这种情况,返回结果的单位都一样,可简化为 =IF(B18>20,4,IF(B18>10,3,2))/1%

        提取身份证的第17位来判断男女,mid(a1,17,1)  可以写为mid(a1,9,9) 既能兼容15位的身份证又少了一个字符.

    仅是个人意见,欢迎指正.
   

meililin

交完作业安心(￣o￣) . z Z
第一题没用IF后公式看起来并没有简化;利用iferror返回值的特性，看起来公式还是没有简化,反而比用if长
第二、三题，还是IF写最短啊

1. d5=IF(C5>B5,B5,B5*0.95)
   
2. d5=((C5>B5)+(C5<B5)*0.95)*B5
   
3. d5=IFERROR(B5/(C5>B5),B5*0.95)

复制代码

1. c18=IF(B18>20,400,IF(B18>10,300,200))
   
2. c18=LOOKUP(B18-0.01,{0,10,20},{200,300,400})
   
3. c18=TEXT(B18,"[<=10]200;[>=21]400;300")-B18
   

复制代码

1. d27=IF(MOD(MID(B27,17,1),2),"男","女")
   
2. d27=LOOKUP(MOD(MID(B27,17,1),2),{0,1},{"女","男"})
   
3. d27=TEXT(MOD(MID(B27,17,1),2),"[=1]男;女")

复制代码

第4题
选中C36:c41；
新建规则公式:=$C36>$B36

76868850

交作业了，交了睡觉。

满坛皆为吾师

第一题

1. =IF(C5>B5,1,0.95)*B5

复制代码

第二题

1. 取巧 =(ROUNDUP(B18/10,)+1)/1%
   
2. 常规 =IF(B18>20,4,IF(B18>10,3,2))/1%
   
3. 常规 =LOOKUP(B18,{0,2;11,3;21,4})/1%

复制代码

第三题

1. =IF(ISEVEN(MID(B27,17,1)),"女","男")
   
2. =IF(MOD(MID(B27,17,1),2),"男","女")
   
3. =CHOOSE(MID(B27,17,1),"男","女")

复制代码

第四题

hsl215

第一题

1. =IF(C5>B5,1,95%)*B5

复制代码

第 二题

1. =IF(B18>20,4,IF(B18>10,3,2))/1%
   
2. =IF(B18<11,2,IF(B18<21,3,4))/1%
   
3. =LOOKUP(B18,{0,2;11,3;21,4})/1%
   
4. =VLOOKUP(B18,{0,2;11,3;21,4},2)/1%
   
5. =HLOOKUP(B18,{0,11,21;2,3,4},2)/1%
   
6. =CHOOSE(MATCH(B18,{0,11,21}),2,3,4)/1%
   
7. =INDEX({2;3;4},MATCH(B18,{0;11;21}))/1%

复制代码

第三题，还可以写出好几个，就不一一写出来了。

1. =IF(MOD(MID(B27,9,9),2),"男","女")
   
2. =IF(MOD(MID(B27,15,3),2),"男","女")
   
3. =IF(MOD(RIGHT(LEFT(B27,17)),2),"男","女")
   
4. =TEXT(-1^MID(B27,9,9),"女;男")
   
5. =TEXT(MOD(MID(B27,9,9),2),"男;;女")
   
6. =CHOOSE(MOD(MID(B27,9,9),2)+1,"女","男")
   
7. =CHOOSE(2^MOD(MID(B27,9,9),2),"女","男")
   
8. =IF(ISODD(MID(B27,9,9)),"男","女")
   
9. =IF(ISEVEN(MID(B27,9,9)),"女","男")

复制代码

第四题
公式

1. =$C36>$B36

复制代码

格式应用于
=$A$36:$C$41

ANDY0393

一：

1. =IF(C5>B5,B5,B5*0.95)
   
2. =B5*(1-0.05*(B5>C5))
   
3. =B5*0.95^(C5<B5)

复制代码

二：

1. =IF(B18>21,400,IF(B18>11,300,200))
   
2. =IF(B18<11,200,IF(B18<21,300,400))
   
3. =LOOKUP(B18,{0,11,21},{2,3,4}/1%)
   
4. =CEILING(B18,10)*10+100

复制代码

三：

1. =IF(MOD(MID(B27,17,1),2),"男","女")
   
2. =IF(MOD(INT(RIGHT(B27,2)/10),2),"男","女")
   
3. =MID(REPT("男女",5),LEFT(RIGHT(B27,2)),1)
   
4. =MID(REPT("男女",5),MID(B27,17,1),1)
   
5. =MID(REPT("男女",5),RIGHT(LEFT(B27,17)),1)
   
6. =TEXT(-1^MID(B27,17,1),"女;男")
   
7. =TEXT(MOD(RIGHT(LEFT(B27,17),1),2),"男;;女")
   
8. =IF(ISODD(MID(B27,17,1)),"男","女")
   
9. =IF(ISEVEN(MID(B27,17,1)),"女","男")

复制代码

四：

1. =$C36>$B36

复制代码

chh0926

1题
=B5-(C5<B5)*B5*5%
2题
=(2+(B18>10)+(B18>20))*100
3题
=TEXT(-1^MID(B27,17,1),"女;男")
4题
选择设置区域，当前单元格在第16行
条件：=$C36>$B36

ldxhzy

一、D5公式：
              =IF(C5>B5,B5,B5*95%)
二、C18公式：
             =IF(B18>21,400,IF(B18>10,300,200))
三、D27公式：
            =IF(MOD(MID(B27,17,1),2),"男","女")
四、1、选中 A36:C41
      2、设置条件格式，公式： =$C36>$B36
      3、设置条件格式的填充色为黄色

sinowonder

1、=IF(C5>B5,B5,B5*95%)
2、=LOOKUP(B18,{0,11,21},{2,3,4}*100)
3、=IF(MOD(MID(B27,17,1),2),"男","女")
4、=$C36>$B36