[已解决]插入排序算法求助

mg0601001

小弟在学习vba排序中的插入排序，以下是自己写的代码，调试了很多次，觉得与兰版的原理差不多，但是就是结果不对，求指教，多谢！
Sub t1()
Dim arr
Dim x, y, k,  tem
arr = Range("a1:a10")
   For x = 2 To UBound(arr)            
      For y = x - 1 To 1 Step -1      
         If arr(y, 1) > arr(x, 1) Then
            arr(y + 1, 1) = arr(y, 1)                  
         Else
            Exit For                  
         End If
      Next y                        
      tem = arr(x, 1)
      arr(x, 1) = arr(y + 1, 1)
      arr(y + 1, 1) = tem
   Next x
  Range("b1").Resize(UBound(arr)) = arr
End Sub

最佳答案

月排行榜 / 总排行榜

香川群子

2014-1-10 16:32

1. 
   
2. Sub test1()
   
3.     arr = Application.Transpose(Range("a1:a10")) '待排序数据转为一维数组以便观察
   
4.     For x = 2 To UBound(arr) '从第2行开始检查至末尾
   
5.         insert_Tmp = arr(x) '把当前行x对应的数值存入【待插入值】即临时变量insert_Tmp
   
6.         For y = x - 1 To 1 Step -1 '倒序检查当前行之前所有行 x-1 to 1
   
7.             If arr(y) > insert_Tmp Then '如果当前行y对应的数值arr(y)比【待插入值】还要大
   
8.                 arr(y + 1) = arr(y)  '那么需要向下一行y+1挪一下位置，留出空位让【待插入值】可以插入
   
9.          'arr(y) = insert_Tmp 'y行中插入【待插入值】……但为了提高效率不要马上插入，这句不执行
   
10.             Else
    
11.                 Exit For '如果当前行y对应数值已经不必【待插入值】大，那么可以确定本次插入位置为y+1
    
12.             End If
    
13.         Next y
    
14.         arr(y + 1) = insert_Tmp '比较结束，按最后确定的插入位置y+1行中插入【待插入值】
    
15.     Next x
    
16.     Range("b1").Resize(UBound(arr)) = Application.Transpose(arr) '向工作表中输出排序结果
    
17. End Sub

复制代码

跳转到最佳答案楼层

苗凱

误导了，呵呵  

CheryBTL

IF里的处理不对，你已经改变了源数据，肯定得不到正确的结果

mg0601001

求楼上详解，多谢！

mg0601001

还不是特别名表，求详解，多谢。

苗凱

Sub t1()
Dim arr
Dim x, y, k,  tem
arr = Range("a1:a10")
   For x = 2 To UBound(arr)   
tem = arr(x, 1)         
      For y = x - 1 To 1 Step -1      
         If arr(y, 1) >  tem  Then
            arr(y + 1, 1) = arr(y, 1)                  
         Else
            Exit For                  
         End If
      Next y                          
      arr(y + 1, 1) = tem
   Next x
  Range("b1").Resize(UBound(arr)) = arr
End Sub

苗凱

你看看，是不是对的，你的错误是把直接比较了，那样的话改变了它的值，需要找一个过度的变量才行，用过度的变量来保存它的值就没有问题了，不知道楼主明白没.?

香川群子

Sub test1()
    arr = Application.Transpose(Range("a1:a10")) '待排序数据转为一维数组以便观察
    For x = 2 To UBound(arr) '从第2行开始检查至末尾
        insert_Tmp = arr(x) '把当前行x对应的数值存入【待插入值】即临时变量insert_Tmp
        For y = x - 1 To 1 Step -1 '倒序检查当前行之前所有行 x-1 to 1
            If arr(y) > insert_Tmp Then '如果当前行y对应的数值arr(y)比【待插入值】还要大
                arr(y + 1) = arr(y)  '那么需要向下一行y+1挪一下位置，留出空位让【待插入值】可以插入
         'arr(y) = insert_Tmp 'y行中插入【待插入值】……但为了提高效率不要马上插入，这句不执行
            Else
                Exit For '如果当前行y对应数值已经不必【待插入值】大，那么可以确定本次插入位置为y+1
            End If
        Next y
        arr(y + 1) = insert_Tmp '比较结束，按最后确定的插入位置y+1行中插入【待插入值】
    Next x
    Range("b1").Resize(UBound(arr)) = Application.Transpose(arr) '向工作表中输出排序结果
End Sub

香川群子

1. 
   
2. Sub test1()
   
3.     arr = Application.Transpose(Range("a1:a10")) '待排序数据转为一维数组以便观察
   
4.     For x = 2 To UBound(arr) '从第2行开始检查至末尾
   
5.         insert_Tmp = arr(x) '把当前行x对应的数值存入【待插入值】即临时变量insert_Tmp
   
6.         For y = x - 1 To 1 Step -1 '倒序检查当前行之前所有行 x-1 to 1
   
7.             If arr(y) > insert_Tmp Then '如果当前行y对应的数值arr(y)比【待插入值】还要大
   
8.                 arr(y + 1) = arr(y)  '那么需要向下一行y+1挪一下位置，留出空位让【待插入值】可以插入
   
9.          'arr(y) = insert_Tmp 'y行中插入【待插入值】……但为了提高效率不要马上插入，这句不执行
   
10.             Else
    
11.                 Exit For '如果当前行y对应数值已经不必【待插入值】大，那么可以确定本次插入位置为y+1
    
12.             End If
    
13.         Next y
    
14.         arr(y + 1) = insert_Tmp '比较结束，按最后确定的插入位置y+1行中插入【待插入值】
    
15.     Next x
    
16.     Range("b1").Resize(UBound(arr)) = Application.Transpose(arr) '向工作表中输出排序结果
    
17. End Sub

复制代码