[已解决]sum(offset())数组函数应用出错

excel盲2013

详见附件。

最佳答案

月排行榜 / 总排行榜

顺⑦.zì繎。

2013-6-2 02:22

第一问：
基于表格都是每月空两行的内容不用计算。所以用OFFSET 参数直接跳过。。公式修改如下

1. =SUM(N(OFFSET($AV21,,3-3*COLUMN($A1:A1))))

复制代码

三键结束。右拉 即可。

第二问：

ROW 跟 COLUMN  都是返回单个值的 数组。。虽然是单个值。但也是数组 ｛｝两个大括号表示了他特殊的身份。

第三问：解惑
问题所在 ：多维引用
OFFSET的的后四个参数。只要有任意一个构成数组。那么OFFSET就构成多维引用。。。｛-2｝已经是单个值的数组。构成多维引用。。多维引用无法用普通函数处理。。。有一些函数可以处理多为引用。。如  :SUBTOTA

1. =SUM(SUBTOTAL(9,OFFSET($AV21,,3-3*COLUMN($A1:A1))))

复制代码

这里的OFFSET 右拉第二参数的公式生成多个值的内存数组。在偏移构成多维引用。。用SUBTOL 求和每个平面的值。在外套SUM求和 即可。。
或者用N函数。。。N函数可以挖取每个平面左上角的数值。。有用我们这里OFFSET 出来的都是 单个单元格的平面所以可以用N函数来解决 如果是多个引用区域的平面 就要适当的考虑你要的是什么结果在决定了。。公式就是第一问的公式。。

SUMIF 求和 多为引用每个平面的值 外套SUM求和。

1. =SUM(SUMIF(OFFSET($AV21,,3-3*COLUMN($A1:A1)),"<>"))

复制代码

SUMIF的条件为为条件求和  “<>”
其他也有一些函数可以在多维引用中使用 在这里就不在一一举例，如 数据库函数。。COUNTIF 。等等。。。。

第四： 解题。。。

1. =SUM(SUMIF($O5:$AV5,COLUMN($A1:A1)&"月",$O21))

复制代码

SUMIF横向条件求和。外套SUM 。

跳转到最佳答案楼层

as0810114

AY7输入公式，右拉，下拉。

1. =SUM($AV7:OFFSET($AV7,,-3*COLUMN(A1)+3))

复制代码

看了半天才看懂。

excel盲2013

as0810114 发表于 2013-6-2 00:00
AY7输入公式，右拉，下拉。看了半天才看懂。

大哥，AO、AR、AU列的比率是不应加进去的。

as0810114

excel盲2013 发表于 2013-6-2 00:16
大哥，AO、AR、AU列的比率是不应加进去的。

那就改成 AY7输入公式

1. =SUM(IF($AV7:OFFSET($AV7,,-3*COLUMN(A1)+3)>1,$AV7:OFFSET($AV7,,-3*COLUMN(A1)+3)))

复制代码

三键数组，右拉下拉
如果解决了，记得设置为最佳答案，谢谢。

excel盲2013

as0810114 发表于 2013-6-2 00:23
那就改成 AY7输入公式三键数组，右拉下拉
如果解决了，记得设置为最佳答案，谢谢。

兴趣是最好的老师，高手是迟早的事情——你已经是高手了。睡了，明早再看吧，赏金迟早是你的。

顺⑦.zì繎。

第一问：
基于表格都是每月空两行的内容不用计算。所以用OFFSET 参数直接跳过。。公式修改如下

1. =SUM(N(OFFSET($AV21,,3-3*COLUMN($A1:A1))))

复制代码

三键结束。右拉 即可。

第二问：

ROW 跟 COLUMN  都是返回单个值的 数组。。虽然是单个值。但也是数组 ｛｝两个大括号表示了他特殊的身份。

第三问：解惑
问题所在 ：多维引用
OFFSET的的后四个参数。只要有任意一个构成数组。那么OFFSET就构成多维引用。。。｛-2｝已经是单个值的数组。构成多维引用。。多维引用无法用普通函数处理。。。有一些函数可以处理多为引用。。如  :SUBTOTA

1. =SUM(SUBTOTAL(9,OFFSET($AV21,,3-3*COLUMN($A1:A1))))

复制代码

这里的OFFSET 右拉第二参数的公式生成多个值的内存数组。在偏移构成多维引用。。用SUBTOL 求和每个平面的值。在外套SUM求和 即可。。
或者用N函数。。。N函数可以挖取每个平面左上角的数值。。有用我们这里OFFSET 出来的都是 单个单元格的平面所以可以用N函数来解决 如果是多个引用区域的平面 就要适当的考虑你要的是什么结果在决定了。。公式就是第一问的公式。。

SUMIF 求和 多为引用每个平面的值 外套SUM求和。

1. =SUM(SUMIF(OFFSET($AV21,,3-3*COLUMN($A1:A1)),"<>"))

复制代码

SUMIF的条件为为条件求和  “<>”
其他也有一些函数可以在多维引用中使用 在这里就不在一一举例，如 数据库函数。。COUNTIF 。等等。。。。

第四： 解题。。。

1. =SUM(SUMIF($O5:$AV5,COLUMN($A1:A1)&"月",$O21))

复制代码

SUMIF横向条件求和。外套SUM 。

顺⑦.zì繎。

建议 观看 小妖同学的 数组中高级教程  在论坛上搜一搜 就找到了。