[已解决]EXCEL无法刷新，

gaofenglaoda1

我把一个工作薄里的4个表用SQL语句做了个数据透视表进销存，可是保存好以后，然后关闭，再打开，点刷新就提提下面的问题，   如果缩小窗口在放大就能刷新了，好像中邪了，求帮助

最佳答案

月排行榜 / 总排行榜

hwc2ycy

2013-5-3 19:45

(, 下载次数: 2)

上传

点击文件名下载附件

跳转到最佳答案楼层

hwc2ycy

你文件没有放在D盘的根目录下吧？

我下了，放在D盘根目录下，刷新正常。
里面的连接字符串给固定了。

gaofenglaoda1

hwc2ycy 发表于 2013-5-3 18:44
你文件没有放在D盘的根目录下吧？

我下了，放在D盘根目录下，刷新正常。

我放在了D盘了啊，怎么改连接字符串啊，

gaofenglaoda1

hwc2ycy 发表于 2013-5-3 18:44
你文件没有放在D盘的根目录下吧？

我下了，放在D盘根目录下，刷新正常。

您关闭以后再打开刷新的吗，，，那我这是什么原因啊

云影

gaofenglaoda1 发表于 2013-5-3 18:57
您关闭以后再打开刷新的吗，，，那我这是什么原因啊

你看一下                有问题么

hwc2ycy

1. Sub test()
   
2.     Dim cnn As Object
   
3.     For Each cnn In ThisWorkbook.Connections
   
4.         With cnn
   
5.             Select Case .Type
   
6.                 Case xlConnectionTypeODBC:
   
7.                     .ODBCConnection.Connection = ChangeConnection(.ODBCConnection.Connection)
   
8.                     .ODBCConnection.SourceDataFile = ThisWorkbook.FullName
   
9.                 Case xlConnectionTypeOLEDB:
   
10.                     .OLEDBConnection.Connection = ChangeConnection(.OLEDBConnection.Connection)
    
11.                     .OLEDBConnection.SourceDataFile = ThisWorkbook.FullName
    
12.             End Select
    
13.         End With
    
14.     Next
    
15. End Sub
    
16. 
    
17. Function ChangeConnection(conn As String) As String
    
18.     Dim iPos As Integer
    
19.     iPos = InStr(conn, "Data Source=")
    
20.     ChangeConnection = Left(conn, iPos - 1) & "Data Source=" & ThisWorkbook.FullName & Mid(conn, InStr(iPos, conn, ";"))
    
21. End Function
    
22. 
    
23. Private Sub Workbook_Open()
    
24.     Call test
    
25. End Sub

复制代码

hwc2ycy

测试了，代码自动修正文件位置，不用担心保存位置后无法刷新。

hwc2ycy

简化下

1. Option Explicit
   
2. 
   
3. Sub test()
   
4.     Dim cnn As Object
   
5.     Dim cnnSub As Object
   
6. 
   
7.     For Each cnn In ThisWorkbook.Connections
   
8.         With cnn
   
9.             Select Case .Type
   
10.                 Case xlConnectionTypeODBC:
    
11.                     Set cnnSub = .ODBCConnection
    
12.                 Case xlConnectionTypeOLEDB:
    
13.                     Set cnnSub = .OLEDBConnection
    
14.             End Select
    
15.             With cnnSub
    
16.                 .Connection = ChangeConnection(.Connection)
    
17.                 .SourceDataFile = ThisWorkbook.FullName
    
18.             End With
    
19.         End With
    
20.     Next
    
21. End Sub
    
22. 
    
23. Function ChangeConnection(conn As String) As String
    
24.     Dim iPos As Integer
    
25.     iPos = InStr(conn, "Data Source=")
    
26.     ChangeConnection = Left(conn, iPos - 1) & "Data Source=" & ThisWorkbook.FullName & Mid(conn, InStr(iPos, conn, ";"))
    
27.     'Debug.Print ChangeConnection
    
28. End Function
    
29. 
    
30. Private Sub Workbook_Open()
    
31.     Call test
    
32. End Sub

复制代码

gaofenglaoda1

云影 发表于 2013-5-3 19:07
你看一下                有问题么

你做好的，和我的路劲不一样，不行，白做

gaofenglaoda1

hwc2ycy 发表于 2013-5-3 19:17
简化下

不知道什么原因至情执行不了，，哎，我放到了this work book里了，.SourceDataFile = ThisWorkbook.FullName 这句执行不了，，难道必须的写VBA吗