[已解决]请教一个查找vba代码。

yslvictor

查找某个班级的学生姓名，并复制。
例如：用vba在A列查找1.2，并把对应的姓名复制到G3往下的单元格中。
说明：各个班级已连续排列在一起，只是人数不定。如图：

vba条件查找并复制.rar (2.54 KB, 下载次数: 13)

2013-4-20 12:48 上传

点击文件名下载附件
先谢谢各位论坛老师。

最佳答案

月排行榜 / 总排行榜

大灰狼1976

2013-4-20 14:40

字典学习中。。。
Private Sub CommandButton1_Click()
Dim i, j, arr, d
i = Range("A" & Rows.Count).End(xlUp).Row
Set d = CreateObject("Scripting.Dictionary")
arr = Range("A3:B" & i).Value
   For j = 1 To i - 2
      If arr(j, 1) = "1.2" Then d(arr(j, 2)) = arr(j, 1)
   Next
Range("G3").Resize(d.Count, 1) = Application.WorksheetFunction.Transpose(d.keys)
Set d = Nothing
End Sub

跳转到最佳答案楼层

我不知道呀

Sub tt2()
    Dim i As Integer
    Dim c As Range
    i = 3
        With Range("a2:a500")
            Set c = .Find("1.2", LookIn:=xlValues)
            If Not c Is Nothing Then
                firstAddress = c.Address
                Do
                    Cells(i, 7) = c.Offset(0, 1)
                    i = i + 1
                    Set c = .FindNext(c)
                Loop While Not c Is Nothing And c.Address <> firstAddress
            End If
        End With

End Sub

无聊的疯子

使用高级筛选

1. 
   
2. Sub cc()
   
3.   Range("A2:B65536").AdvancedFilter 2, Range("E2:E3"), Range("G2"), True
   
4. End Sub
   

复制代码

2  表示将结果Copy 到其它区域
Range("E2:E3")  为包含字段名称的条件区域  
  E2 内容"班级"
  E3 内容 "1.2"
Range("G2")  Copy到的目标单元格,该单元格中内容为要Copy出来的字段
  G2 内容"姓名"  ,则将符合条件的 姓名 Copy 过来
  G2 内容"班级"  ,则将符合条件的 班级 Copy 过来
True  表示 筛选不重复值,若姓名中有重复值,请修改为 False

示例说明:
  E2 内容"班级"
  E3 不填入任何内容
修改 G2 单元格为 班级,运行上面的代码,则提取不重复的班级
结果为 1.1,1.2,1.3,1.4

大灰狼1976

字典学习中。。。
Private Sub CommandButton1_Click()
Dim i, j, arr, d
i = Range("A" & Rows.Count).End(xlUp).Row
Set d = CreateObject("Scripting.Dictionary")
arr = Range("A3:B" & i).Value
   For j = 1 To i - 2
      If arr(j, 1) = "1.2" Then d(arr(j, 2)) = arr(j, 1)
   Next
Range("G3").Resize(d.Count, 1) = Application.WorksheetFunction.Transpose(d.keys)
Set d = Nothing
End Sub

yslvictor

谢谢各位论坛老师。我觉得字典的算法要快点。

大灰狼1976

第一次被选为最佳答案，好激动！{:091:}

sjzzhangjun

学习到了