[已解决]请教个LOOKUP函数的问题

1091126096

请教个LOOKUP函数的问题，要求在附件里。

最佳答案

月排行榜 / 总排行榜

高

2011-10-17 12:39

LOOKUP(1,0/((G$2:G$100=A2)*(H$2:H$100=B2)),I$2:I$100)
1、((G$2:G$100=A2)*(H$2:H$100=B2))意思是：G2：G100列中等于A2就返回true;H2：H100等于B2就返回true,否则返回false,这两部分返回的true或者false对应相乘。得到99个数，其中有0，也有1
2、让0除以上面的式子，就会有99个结果，其中有若干个0，也有若干个错误值。
3、用lookup查找1（也可以查找其他大于0的数，也就是说，这里不一定是1），因为lookup是模糊查找，由于找不到1，但是能找到0，就返回在I2：I100中对应这些0的单元格的数值。

跳转到最佳答案楼层

zhc3288

回复 1091126096 的帖子

=INDEX(I2:I5,MATCH(A2&B2,G2:G5&H2:H5,))
三键结束

1091126096

回复 zhc3288 的帖子

你的公式简洁，不错。不过我在学LOOKUP函数，我试过=LOOKUP(1,0/((G$2:G$100=A2)*(H$2:H$100=B2)),I$2:I$100)也能用，但不明白1,0/的含义，可否指点。

lzclzch

=LOOKUP(1,0/((G$2:G$100=A2)*(H$2:H$100=B2)),I$2:I$100)                                                                                                                                   0/false=错误值  0/true=0

请看下面解释

A	B
频率	颜色
4.14	red
4.91	orange
5.17	yellow
5.77	green
6.39	blue
公式	说明（结果）
=LOOKUP(4.91,A2:A6,B2:B6)	在 A 列中查找 4.91，并返回同一行 B 列的值 (orange)
=LOOKUP(5.00,A2:A6,B2:B6)	在 A 列中查找 5.00，并返回同一行 B 列的值 (orange)
=LOOKUP(7.66,A2:A6,B2:B6)	在 A 列中查找 7.66（最接近的下一个值为 6.39），并返回同一行 B 列的值 (blue)
=LOOKUP(0,A2:A6,B2:B6)	在 A 列中查找 0，由于 0 小于查找向量 A2:A7 中的最小值，所以返回错误值 (#N/A)

1091126096

回复 lzclzch 的帖子

这个我知道。不能解决我的疑问。

lzclzch

回复 1091126096 的帖子

你的问题是什么呢?

1091126096

回复 lzclzch 的帖子

例如，=LOOKUP(1,0/((G$2:G$100=A2)*(H$2:H$100=B2)),I$2:I$100)，不明白1,0/的含义，可否指点。

llplj

1是要查找的条件   
0是用来计算公式的值的
这两个数值再这个公式里面没有联系啊

高

LOOKUP(1,0/((G$2:G$100=A2)*(H$2:H$100=B2)),I$2:I$100)
1、((G$2:G$100=A2)*(H$2:H$100=B2))意思是：G2：G100列中等于A2就返回true;H2：H100等于B2就返回true,否则返回false,这两部分返回的true或者false对应相乘。得到99个数，其中有0，也有1
2、让0除以上面的式子，就会有99个结果，其中有若干个0，也有若干个错误值。
3、用lookup查找1（也可以查找其他大于0的数，也就是说，这里不一定是1），因为lookup是模糊查找，由于找不到1，但是能找到0，就返回在I2：I100中对应这些0的单元格的数值。