vba类模块浅显学习之九，类模块接管对象事件

wbzxz · 发表于 2011-4-17 21:43

本帖最后由 wbzxz 于 2011-4-18 08:34 编辑

嘿嘿，这一节的标题是我自己瞎诌的，没有人这样说，但是我又不知道该如何描述，就起了这样一个标题。如何写好这篇心得，我苦思冥想了很久，因为我确实没有理解透彻的，但是学习总不能止步不前，我理解多少，就分享多少吧，希望以后能有机会来完善他。

本节学习之前的预备例子

进行本节分享之前，我们对前面的知识稍微进行一下深入，举一个对象变量做为属性的例子：

例子描述：我们在类模块中定义两个公有变量作为属性，与前面的例子不同的是，这次定义的变量是两个对象变量（前面的例子是字符串或整型变）；由于对象变量的特殊性，所以这两个属性可以具有Range类型的特征，可以赋值，具有多种方法，虽然我们初次使用不太习惯，但是仔细想想，是合理的：

类模块中的代码：

'定义了两个Range类的对象变量rng1和rng2，做为"类1"的两个属性
Public rng1 As Range
Public rng2 As Range

复制代码

我们采用了最简单的属性定义的方法。

标准模块代码：

Sub test()
Dim myClass As 类1 '定义类1的对象变量myClass
Set myClass = New 类1 '新建对象(类1的实例)，然后将对对象的引用赋值给对象变量myClass
'下面这个赋值过程需要理解清楚，rng1，rng2作为myClass的两个属性，实际上就是两个变量(myClass本身就是变量)
'rng1与rng2被声明为Range类型，所以他们就是对象变量
'所以，我们就像平常使用对象变量一样使用myClass.rng1和myClass.rng2，使用range的属性和方法，甚至事件
Set myClass.rng1 = Sheet1.Range("A1") '把对Sheet1.Range("A1")对象的引用赋值给myClass的属性rng1
Set myClass.rng2 = Sheet1.Range("A2") '把对Sheet1.Range("A2")对象的引用赋值给myClass的属性rng2
'下面我们可以看出来，给myClass.rng1赋值，就是相当于给Sheet1.Range(""A1"")赋值
myClass.rng1 = 1
MsgBox "myClass.rng1的值是:" & myClass.rng1
MsgBox "Sheet1.Range(""A1"")的值是:" & Sheet1.Range("A1")
'下面我们可以看出，给Sheet1.Range("A2")赋值，就是相当于给myClass.rng2赋值
Sheet1.Range("A2") = 2
MsgBox "myClass.rng2的值是:" & myClass.rng2
MsgBox "Sheet1.Range(""A2"")的值是:" & Sheet1.Range("A2")
'下面的语句我们可以看出来myClass.rng1和myClass.rng2可以使用Range类的方法
myClass.rng1.Clear
MsgBox "利用myClass.rng1.clear方法清除A1单元格内容"
myClass.rng2.Clear
MsgBox "利用myClass.rng2.clear方法清除A2单元格内容"
End Sub

复制代码

通过上面的代码，我们可以看出，当我们用对象变量作为类的属性的时候，这个类的属性就具有了所引用对象的特征，可以使用该对象的属性和方法。

类模块基本示例9.rar (10.62 KB, 下载次数: 98)

2011-4-17 21:36 上传

点击文件名下载附件

正式开始本节的分享

上面的例子，我们用Range类的对象变量做为类的属性rng1，rng2，所以我们可以给rng1，rng2进行赋值，可以使用clear方法，但是，由于Range类没有事件，所以，我们无从知道，类的属性是对象变量的时候，对象的事件他是如何处理的。
为了搞清楚将对象变量做为类模块的属性的时候，类模块的属性是如何处理事件的，我们来找一个带有事件的对象，来进行测试。

例子描述：建立一个窗体，里面有两个按钮对象；建立一个类模块，用按钮类定义一个对象变量作为类的属性，在类模块中为属性写了事件过程；在窗体模块中，定义了两个类1的对象变量，然后把属性与窗体中的按钮连接起来，这样，在类模块中的事件过程就把窗体按钮的事件接管啦（我叫他接管，还没有在那本书里面见到过这种说法，主要是为了理解）。

估计看了这么一段话，你都晕了吧，其实我都已经晕啦，看看实例吧。

类模块：

Public WithEvents cmd As CommandButton
Private Sub cmd_Click()
MsgBox "我是靠类模块属性的事件激活的，我的标题名称是" & cmd.Caption
End Sub

复制代码

这个类模块中代码不难，我们一句一句来看
（1）
Public WithEvents cmd As CommandButton
这句意思是说，以CommandButton类为模板，定义了一个对象变量cmd，由于CommandButton这个类有事件，我们要使用他的事件，就用了WithEvents关键字（就和我们平常的声明变量语句一样，不过多了个关键字而已，这个关键字和事件有关，以后记住，定义对象变量的时候，想用这个对象的事件，就加上这个关键字）

如果您不太清楚，看看这个帖子吧。
http://www.excelpx.com/thread-170919-1-1.html

（2）
Private Sub cmd_Click()
MsgBox "我是靠类模块属性的事件激活的，我的标题名称是" & cmd.Caption
End Sub
这个过程应该不难理解吧，因为cmd属性是CommandButton类的对象变量，所以他可以使用这个事件，我们把事件过程写在了类模块里面；

窗体模块：

Dim myCls1 As 类1 '定义类1的对象变量myCls1
Dim myCls2 As 类1 '定义类1的对象变量myCls2
Private Sub UserForm_Initialize()
Set myCls1 = New 类1 '新建对象(类1的实例)，然后将对对象的引用赋值给对象变量myCls1
Set myCls2 = New 类1 '新建对象(类1的实例)，然后将对对象的引用赋值给对象变量myCls2
'下面的这个语句，就把CommandButton1，CommandButton2这两个按钮对象的事件“出卖”给了myCls1和myCls2的属性
Set myCls1.cmd = Me.CommandButton1 '把对CommandButton1对象的引用赋值给myCls1的属性cmd
Set myCls2.cmd = Me.CommandButton2 '把对CommandButton2对象的引用赋值给myCls2的属性cmd
End Sub

复制代码

标准模块：

Sub test()
UserForm1.Show
End Sub

复制代码

试着把上面的代码运行一下（提供有附件），你会发现，虽然你没有在窗体中为CommandButton1和CommandButton2对象的click事件写过程，但是当你单击这两个按钮的时候，仍旧执行了单击过程，执行了哪里过程呢？过程在类模块里面，类模块属性中的单击事件“接管”了窗体中CommandButton1和CommandButton2对象的单击事件。

通过上面的叙述，不知道您理解了没有，其实这一节我主要是想分享：
在类模块中，我们定义变量的时候（也就是我们说的类模块的属性）需要定义对象变量，并且这个对象类拥有事件（比如worksheet，workbook，command，textbox等等），同时我们需要使用（我称之为“接管”）这个事件，我们就要完成以下两方面的工作：

1、类模块中输入Public WithEvents 对象变量名 As 对象类
这是说我们要声明一个对象变量（作为类模块的一个属性），同时要使用这个对象类的事件；
注意：不想用事件的时候，就不要用WithEvents关键字；
2、在其他模块中：
（1）声明类模块的对象变量；
（2）新建类模块的对象（实例），并将对象引用赋值给声明的对象变量；
（3）将对象变量的属性与要接管事件的对象连接起来；

这样子，你就可以完成了事件的接管工作，呵呵。

类模块基本实例10.rar (11.66 KB, 下载次数: 122)

放浪形骸 · 发表于 2011-4-17 22:17

学习下，超级赞啊

witolion · 发表于 2014-12-10 16:55

有个疑问：
我试了一下，声明类模块的对象变量如果放在过程中，执行就没反应。
一定要放在模块前面才行，为何？
求解惑。

匿名 *发表于 2015-1-2 10:16* · 发表于 2015-1-2 10:16

超级赞一个。
我在网上看了很多类模块方面的资料，看得我稀里糊涂。楼主九个系列的讲座让我受益匪浅。再次感谢楼主。

顺祝新年快乐！

metoo77 · 发表于 2015-7-4 13:24

楼主真不错啊! 很感谢楼主的无私分享
另外vba类模块浅显学习之八，类模块自定义事件好像被删除了

yangkeyuan · 发表于 2015-7-12 08:23

谢谢分享！

ddbb2008 · 发表于 2021-5-14 16:24

第八个帖子删了？

		自动登录	找回密码
密码			注册

[分享] vba类模块浅显学习之九，类模块接管对象事件

评分