“如何补足缺少考勤的日期”中数组和字典代码解释（二）

zgwei050

具体问题见：http://www.excelpx.com/thread-162318-1-1.html
这是检查加班情况的代码（数组+字典），相对简单一些，供初学者参考。附件见检查缺勤情况的代码：
http://www.excelpx.com/forum.php?mod=viewthread&tid=162751&page=1#pid2495143

1. 
   
2. Sub 检查加班情况()
   
3. Dim WSa As Worksheet, WSb As Worksheet '定义各种变量
   
4. Dim d As Object
   
5. Dim i As Long, j As Long, n As Long
   
6. Dim LastRowA As Long, LastRowB As Long
   
7. Dim arr1, arr2, brr()
   
8. Dim Myname
   
9.   On Error Resume Next '容错处理
   
10.   Set d = CreateObject("Scripting.Dictionary") '定义字典d
    
11.   Set WSa = Sheets("应工作日期") '设置WSa为"应工作日期"工作表
    
12.   Set WSb = Sheets("现工作日期") '设置WSb为"现工作日期"工作表
    
13.   LastRowA = WSa.Cells(Rows.Count, 1).End(xlUp).Row '计算"应工作日期"工作表中A列数据最后一行行数
    
14.   LastRowB = WSb.Cells(Rows.Count, 3).End(xlUp).Row '计算"现工作日期"工作表中A列数据最后一行行数
    
15.   arr1 = WSa.Range("A2:A" & LastRowA) '定义"应工作日期"工作表中A列数据区为arr1数组
    
16.   arr2 = WSb.Range("C2:D" & LastRowB) '定义"现工作日期"工作表中C和D列数据区为arr2数组
    
17.   For i = 1 To UBound(arr2) '提取"现工作日期"工作表C列不重复“姓名”数据
    
18.     d(arr2(i, 1)) = ""
    
19.   Next i
    
20.   For Each Myname In d.keys '对于每个姓名而言，
    
21.     For j = 1 To UBound(arr1)
    
22.       d(Myname & arr1(j, 1)) = ""
    
23.            '与"应工作日期"工作表中A列数据区数据一一组合——
    
24.                      '产生一个“姓名&日期”不重复组合数据——记录每个员工必须出勤的情况
    
25.     Next j
    
26.   Next
    
27.       '下面比较应出勤情况(d)与现有记录的员工出勤情况
    
28.   For i = 1 To UBound(arr2)
    
29.     If Not d.exists(arr2(i, 1) & arr2(i, 2)) Then '如果“现有记录”中有记录，但“应出勤记录”中并没有找到——这就是加班记录
    
30.       n = n + 1 '计数
    
31.       ReDim Preserve brr(1 To 2, 1 To n) '动态定义数组brr——记录相应的加班记录
    
32.       brr(1, n) = arr2(i, 1) '加班姓名记录
    
33.       brr(2, n) = arr2(i, 2) '加班日期记录
    
34.     End If
    
35.   Next i
    
36.   WSb.Range("I2:J" & Rows.Count) = "" '清空原来的记录
    
37.   WSb.Range("I2").Resize(UBound(brr, 2), 2) = Application.Transpose(brr) '显示加班记录
    
38.   Set d = Nothing
    
39. End Sub

复制代码

老糊涂

谢谢分享  

linuvzg

謝謝分享

444172107

谢谢分享，写的好详细，新手看着很给力，万分感谢