[已解决]请教一个排序的问题

fjmxwrs · 发表于 2010-5-31 13:38

请教一个排序的问题，说明在表中，能用V更好，谢谢各位指教。

eA6waUzS.rar (4.52 KB, 下载次数: 2)

wayy · 发表于 2010-5-31 13:40

数据在输入时可以使用自定义格式，然后直接排序就可以了。

fjmxwrs · 发表于 2010-5-31 13:55

QUOTE:

以下是引用wayy在2010-5-31 13:40:00的发言：
数据在输入时可以使用自定义格式，然后直接排序就可以了。

自定义格式，怎么写？谢谢

amulee · 发表于 2010-5-31 14:21

这个最佳答案由 amulee 给出，感谢 amulee 的回答。

单击隐藏图章

Sub 排序()
    Dim ArrYS, i&, j%, Temp1, Temp2, Rng As Range, Temp$
    Set Rng = Range("A1:B" & Range("A65536").End(xlUp).Row)
    ArrYS = Rng
    Temp = "一二三四五六七八九十"
    '格式化各班级
    For i = 2 To UBound(ArrYS)
        Temp1 = Int(InStr(1, Temp, Left(ArrYS(i, 2), 1)))
        Temp2 = Right(ArrYS(i, 2), Len(ArrYS(i, 2)) - 3)
        ArrYS(i, 2) = Temp1 * 100 + Int(Left(Temp2, Len(Temp2) - 1))
    Next i
    Rng = ArrYS
    '排序。利用系统排序
    Rng.Sort Key1:=Range("B2"), Order1:=xlAscending, Key2:=Range("A2") _
        , Order2:=xlAscending, Header:=xlYes
    '恢复原来班级
    ArrYS = Rng
    For i = 2 To UBound(ArrYS)
        Temp1 = Mid(Temp, ArrYS(i, 2) \ 100, 1) & "年级"
        ArrYS(i, 2) = Temp1 & (ArrYS(i, 2) Mod 100) & "班"
    Next i
    Rng = ArrYS
End Sub

fjmxwrs · 发表于 2010-5-31 14:27

感谢4楼老师的回答，就是不理解，可以注一下每行的注释吗？谢谢

amulee · 发表于 2010-5-31 14:33

Sub 排序()
    Dim ArrYS, i&, j%, Temp1, Temp2, Rng As Range, Temp$
    Set Rng = Range("A1:B" & Range("A65536").End(xlUp).Row)
    ArrYS = Rng
    Temp = "一二三四五六七八九十"
    '格式化各班级
    For i = 2 To UBound(ArrYS)
        Temp1 = Int(InStr(1, Temp, Left(ArrYS(i, 2), 1)))   '取左边大写一二三四等转化为数字
        Temp2 = Right(ArrYS(i, 2), Len(ArrYS(i, 2)) - 3)    '取班级数字
        ArrYS(i, 2) = Temp1 * 100 + Int(Left(Temp2, Len(Temp2) - 1))    '转化年纪班级为数字=年级*100+班级
    Next i
    Rng = ArrYS '将上述转化结果再写入工作表
    '排序。利用系统排序
    Rng.Sort Key1:=Range("B2"), Order1:=xlAscending, Key2:=Range("A2") _
        , Order2:=xlAscending, Header:=xlYes
    '恢复原来班级
    ArrYS = Rng '得到排序后的结果
    For i = 2 To UBound(ArrYS)
        Temp1 = Mid(Temp, ArrYS(i, 2) \ 100, 1) & "年级"    '将年级转化为大写数字
        ArrYS(i, 2) = Temp1 & (ArrYS(i, 2) Mod 100) & "班" '将年级班级写入
    Next i
    Rng = ArrYS '输出最终结果
End Sub

fjmxwrs · 发表于 2010-5-31 14:34

谢谢老师，慢慢领会学习。谢了

[此贴子已经被作者于2010-5-31 14:34:19编辑过]

		自动登录	找回密码
密码			注册